Programming a Channel Power Measurement

General Programming Procedure

1. Prompt the user to connect the access terminal to the test set's front panel RF IN/OUT connector and power it on. Instruct the user that if the access terminal does not automatically open a session, perform whatever actions are necessary to open a session. See Establish a Session from the Access Terminal for more details.
2. Prompt the user to establish an RTAP data connection. See Step 4: Make a connection for more details.
3. If you will be measuring very low access terminal power levels, turn the Call Drop Timer off to prevent dropping the connection, using the CALL:CONNected:DROP:TIMer[:STATe]<[:SELected]|:TA856> command.
4. Set up the channel power measurement parameters as needed using the SETup:CPOWer commands.
5. Set cell power as needed using the CALL:POWer command.
6. Set the Reverse Closed Loop Power Control mode as needed using the CALL[:CELL[1]]:CLPControl:REVerse:MODE<[:SELected]|:TA856> command.
7. Initiate the channel power measurement using the INITiate:<measurement mnemonic>[:ON] command. The <measurement mnemonic> for the channel power measurement is CPOWer.
8. Use the FETCh:CPOWer commands to obtain the measurement results. (You can also replace steps 7 and 8 with a single command - READ:CPOWer[:ALL]? ).

Programming Example: 4.3.5 Minimum Controlled Output Power

 
10 ! 4.3.5 Minimum Controlled Output Power
20 ! This programming example assumes the access terminal
30 ! is connected to the test set and in a 9.6 kbps
40 ! RTAP data connection.
50 !
60       Testset=714
70 !
80       DISP "Measuring Minimum Power"
90 !
100 !***Set up test parameters***
110 !
120       Ior=-25
130       ! Cell power for test
140 !
150       OUTPUT Testset;"CALL:CONNECTED:DROP:TIMER:STATE 0"
160       ! Turn the call drop timer off
170 !
180 !***Set up measurement parameters***
190 !
200       OUTPUT Testset;"SETUP:CPOWER:CONTINUOUS OFF"
210       ! Set measurement to single trigger
220       OUTPUT Testset;"SETUP:CPOWER:TIMEOUT .5"
230       ! Set Channel Power timeout to 0.5 sec
240 !
250 !***Set test conditions***
260 !
270       OUTPUT Testset;"CALL:POW ";Ior
280       ! Set cell power for test
290       OUTPUT Testset;"CALL:CLPCONTROL:REVERSE:MODE DOWN"
300       ! Start transmission of All Down (1) power control bits
310       WAIT 1
320       ! Settling time for mobile output power to slew down
330 !
340 !***INITiate and FETCh measurements***
350 !
360       OUTPUT Testset;"INITIATE:CPOWER"
370       ! Initiate a channel power measurement
380       OUTPUT Testset;"FETCh:CPOWER?"
390       ! Fetch channel power measurement results
400       ENTER Testset;Integrity,Channel_power
410       ! Read Integrity bit and channel power result
420 !
430 !***Print measurement results***
440 !
450       CLEAR SCREEN
460       PRINT "Minimum Power Test Results:"
470       PRINT
480       PRINT "Integrity Indicator          = ",Integrity
490       PRINT "Minimum Power (dBm/1.23 MHz) = ",Channel_power
500       PRINT
510       PRINT "Minimum Controlled Output Power Test Complete"
520 !
530 !***Post test clean up***
540 !
550       OUTPUT Testset;"CALL:CLPCONTROL:REVERSE:MODE ACTIVE"
560       ! Return to active power control bits
570       OUTPUT Testset;"CALL:POW -55"
580       ! Set cell power back to initial level
590       OUTPUT Testset;"CALL:CONNECTED:DROP:TIMER:STATE 1"
600       ! Return call drop timer to ON
610       OUTPUT Testset;"INIT:CPOW:OFF"
620       ! Turn channel power off
630       DISP ""
640 !
650       END

Related Topics

Channel Power Measurement Description

Manual Operation: Measuring Channel Power

Channel Power Measurement Troubleshooting

4.3.5 Minimum Controlled Output Power

Programming: Getting Started Guide for 1xEV-DO Terminal Test