Programming a TX Dynamic Power Measurement

Last updated: May 24, 2006

This section provides an example of how to make a TX dynamic power measurement via GPIB.

The following program example assumes that the access terminal (AT) is connected to the test set's RF IN/OUT connector.

Since the measurement is expected to be used only when data connection status is Idle, no data connection is needed.

The basic procedure to measure TX dynamic power is as follows:

Set the test set's receiver to the proper power and frequency using the RFANalyzer:CONTrol:POWer:AUTO , RFANalyzer:MANual:POWer<[:SELected]|:DIGital856> and RFANalyzer:MANual:MEASurement[:MFRequency] commands.
Set the TX dynamic power setup parameters to match your AT's power sequence using the SETup:CTDPower commands.
Place your AT into the test mode required for performing TX dynamic power and order it to transmit continuously at the initial transmit power level.
Initiate (arm) the TX dynamic power measurement using the INITiate:<measurement mnemonic>[:ON] command.
Using the AT's test mode interface, command your AT to generate the RF rise needed to trigger the measurement.
When the measurement is finished, use the FETCh:CTDPower commands to obtain the measurement results.

NOTE

The buffer size for the measurement results should be set above 1445 characters. If the results are printed in format display, you should assign larger buffer size. See example below.

Programming Example

 
10       CLEAR SCREEN
20       DIM Dypow_res$[3400]
30       DIM Dynamic_val(200)
40       !
50       !The size of buffer which contains the return value
60       !should be set above 1445. It is suggested to be 1450.
70       !The buffer size is suggested to be set above 3400 if
80       !the results are displayed with print format as shown below.
90       Testset=714
100       !
110       ON TIMEOUT 7,20 CALL Timeout
120       !Calls "Timeout" routine
130       OUTPUT Testset;"SYST:COMM:GPIB:DEB:STAT ON"
140       !Turns GPIB debug state on
150       !
160       PRINT "***Set up measurement parameters***"
170       !
180       OUTPUT Testset;"SETUP:CTDPOWER:TIMEOUT:STIME 20 S"
190       !Sets measurment timeout to 20 seconds
200       !
210       !***Set up measurement parameters***
220       OUTPUT Testset;"RFAN:CONT:POW:AUTO OFF"
230       !Sets the receiver power control to manual mode
240       OUTPUT Testset;"RFAN:MAN:POW:SEL 0 dBm"
250       !Sets the receiver power to the initial power (max power)
260       !at which the AT will transmit.
260       OUTPUT Testset;"RFAN:MAN:MEAS:MFR 851 MHZ"
270       !Sets the frequecy at which the AT will transmit
280       OUTPUT Testset;"SETUP:CTDP:STEP:LEV -1.0 dB"
290       !Set the dynamic power measurement step size to -1.0 dB
300       OUTPUT Testset;"SETUP:CTDP:STEP:COUN 29"
310       !Set the dynamic power measurement number of Steps
320       !to 30.
330       !
340       PRINT "***Arm the TX dynamic power measurement***"
350       OUTPUT Testset;"INITIATE:CTDPOWER:ON"
360       !Initiate TX dynamic power measurement
370       !
380       PRINT "***Command the AT to trigger the measurement***"
390       !This depends upon the design of the AT.
400       !***Obtain measurement results***
410       PRINT "***Obtain measurement results***"
420       OUTPUT Testset;"FETCH:CTDPOWER:COUNT:STEP?"
430       ENTER Testset;Numofstep
440       OUTPUT Testset;"FETCh:CTDPOWER?"
450       ENTER Testset;Integrity,Dypow_res$
460       !***Display measurement results
470       PRINT "Integrity indicator = ";Integrity
480       PRINT "The number of Step = ";Numofstep
490       FOR I=1 TO Numofstep
500         Dynamic_mkr=((I-1)*17)
510         !Set up a marker that will jump to each comma in the ascii string
520         Dynamic_val(I)=VAL(Dypow_res$[Dynamic_mkr+1;Dynamic_mkr+16])
530         !Convert ascii to a numeric value
540         PRINT "Dynamic ";I-1;" measurement is ";Dynamic_val(I);" dBm/1.23 MHz"
550       NEXT I
560      !
570       END
580  Timeout: SUB Timeout            ! Global timeout handler
590         PRINT "Program timed out"
600         CLEAR 7
610         CLEAR 714
620       SUBEND

The measurement results include an integrity indicator followed by power results for AT initial transmit power and each of the successive down steps.

Programming a TX Dynamic Power Measurement

Programming Example

Related Topics