Step 5: INITiate and FETCh Measurements

Last updated: April 14, 2005

In this step you configure any parameters that are required for the test you are performing, then initiate the measurement and fetch the results. You can also use the READ command to both start the measurement and retrieve the results instead of using the INITiate/FETCh commands.

If the test conditions (cell power, parameter settings, etc.) for any tests are identical, and the required measurements are concurrent (see Concurrent Measurements ), you can perform the tests simultaneously, saving test time. To do this you must use the INITiate/FETCh commands along with the INITiate:DONE? command.

NOTE

The INIT:DONE? command is only useful when performing concurrent testing. When initiating only one measurement at a time, simply send the INITiate command immediately followed by the FETCh command to retrieve the results.

An excerpt from the comprehensive example program is shown below:

 
5520 !*******************************************************************
5530 ! Subroutine: Digital Average Power and
5540 !             TX Spurious Emissions Measurements
5550 !             3.1.2.3.4 Maximum RF Output Power
5560 !             3.1.2.4.1 Conducted Spurious Emissions
5570 !*******************************************************************
5580 !
5590       DISP "Measuring Maximum Power and TX Spurious Emissions"
5600 !
5610 !***Set up test parameters***
5620 !
5630       Ior=-105.5                   ! Set cell power for test
5640 !
5650       IF Band$="KPCS" OR Band$="USPCS" OR Band$="IMT2000" THEN
5660       ! Set open loop adjust for test
5670           Ol_adjust=84
5680       ELSE
5690           Ol_adjust=81
5700       END IF
5710 !
5720       OUTPUT Testset;"CALL:APPLICATION:RTAP:DRATE BPS153600"
5730       ! Set RTAP data rate to 153600
5740       OUTPUT Testset;"CALL:APAR:POWER:OLADJUST ";Ol_adjust
5750       ! Set Open Loop Adjust
5760       OUTPUT Testset;"CALL:APAR:PROBE:IADJUST 15"
5770       ! Set Probe Initial Adjust
5780       OUTPUT Testset;"CALL:APAR:PROBE:STEP:COUNT 15"
5790       ! Set Probe Num Steps
5800       !OUTPUT Testset;"CALL:APAR:PROBE:SEQUENCE 15"
5810       ! Set Probe Sequence Max - this parameter setting is required
5820       ! by C.S0033 but does not affect test results. It is a legacy
5830       ! parameter setting from IS-98. Changing this parameter drops
5840       ! the connection, as required by C.S0024. It is recommended not
5850       ! to send this command.
5860       OUTPUT Testset;"CALL:APAR:PROBE:POWER:STEP 7.5"
5870       ! Set Probe Step

5960 !***Set test conditions***
5970 !
5980       OUTPUT Testset;"CALL:POW ";Ior
5990       ! Set Cell Power for Test
6000       OUTPUT Testset;"CALL:CLPCONTROL:REVERSE:MODE UP"
6010       ! Start transmission of All Up (0) power control bits
6020       WAIT 1
6030       ! Settling time to allow mobile power to slew up to maximum power
6040 !
6050 !***Obtain measurement results***
6060 !
6070       OUTPUT Testset;"INITIATE:DAPOWER;CTXS"
6080       ! Initiate digital average power and
6090       ! TX spurious emissions measurements
6100 !
6110       LOOP
6120           OUTPUT Testset;"INIT:DONE?"
6130           ! Determine if a measurement is done
6140           ENTER Testset;Meas_done$
6150           ! Obtain measurement results as they are ready
6160 !
6170           SELECT Meas_done$
6180           CASE "DAP"
6190               OUTPUT Testset;"FETCh:DAPOWER?"
6200               ENTER Testset;Integrity,Avg_power_dbm
6210           CASE "CTXS"
6220               OUTPUT Testset;"FETCH:CTXS?"
6230               ENTER Testset;Ctxs_integ,Ctxs_pf,Low_adj,Upp_adj,Low_alt,Upp_alt
6240           END SELECT
6250 !
6260       EXIT IF Meas_done$="NONE"
6270       ! Exit loop when all measurements are complete
6280       END LOOP
6290       ! If Meas_done$="WAIT" then loop continues until "NONE"

Step 5: INITiate and FETCh Measurements

Navigation