Programming a Graphical Access Probe Power Measurement

General Programming Procedure

1. Prompt the user to connect the access terminal to the test set's front panel RF IN/OUT connector and power it on. Instruct the user that if the access terminal does not automatically open a session, perform whatever actions are necessary to open a session. See Establish a Session from the Access Terminal for more details.
2. Set up the access parameters (such as power step size, number of steps, etc.) as needed using the CALL:APARameter commands.
3. Set up the graphical access probe power measurement parameters. Turn on the graphical access probe power measurement timeout timer on using the SETup:GAPPower:TIMeout[:STIMe] command. If the timeout timer is not turned on, and an access probe is not received, the measurement will hang on the FETCh? command indefinitely.
4. Turn on call limit mode so the test set does not acknowledge the access terminal's access attempt, using the CALL:CONNected:LIMit[:STATe]<[:SELected]|:TA856> command. You must set all parameters that are configured during the Session Negotiate state (such as Probe Sequence Max ) before turning call limit mode on (see Call Limit Mode for more information).
5. Set cell power as needed using the CALL:POWer command.
6. Page the access terminal (to initiate access probes) using the CALL:FUNCtion:DATA:STARt command.
7. Initiate the access probe power measurement using the INITiate:<measurement mnemonic>[:ON] command. The <measurement mnemonic> for the access probe power measurement is GAPPower.
8. Use the FETCh:GAPPower[:ALL][:RANGe20]? or FETCh:GAPPower[:ALL]:RANGe60? commands to obtain the measurement results. (You can also replace steps 7 and 8 with a single command - READ:GAPPower[:ALL][:RANGe20]? or READ:GAPPower[:ALL]:RANGe60? ).
9. Use the CALL:FUNCtion:DATA:STOP command to stop paging the access terminal.

Programming Example: 4.3.1 Range of Open Loop Output Power

 
10 !**********************************************************************
20 ! 4.3.1 Range of Open Loop Output Power
30 !This programming example assumes the access terminal
40 !is connected to the test set and in the session open state.
41 !This example commands the AT send 5 access probes for each test.
50 ! 
60  Testset=714
70  DISP "Testing Range of Open Loop Power"
80 !
90 !***Test parameters variables***
100     Ior1=-25       !First level for test
110     Ior2=-65       !Second level for test
120     Ior3=-93.5       ! Ior for test 3 Band Class 0, AT Class III
130     Ol_adjust=78       ! Set Open Loop Adjust for Band Class 0
140     Preamble_len=7       !Set Preamble Length to 7 frames
150     Prb_ini_adj=0       !Set Probe Initial Adjust to 0 dB
160     Prb_pwr_step=0
170     !Set Probe Power Step to 0 dB. This is to ensure that
180     !all access probes in the probe sequence will transmit at
190     !the same power level so that you can easily verify the test.
200     Prb_num_step=4       !Set Probe Num Step to 4
210     Prb_seq_max=1       !Set Probe Sequence Max to 1
220     Total_probes= Prb_num_step*Prb_seq_max
230     !total number of access probes to be measured
240 !        
250 !***Set up access parameters***
260 OUTPUT Testset;"CALL:APAR:POWER:OLADJUST ";Ol_adjust
270 ! Set Open Loop Adjust
280 OUTPUT Testset;"CALL:APAR:PREAMBLE:LENGTH ";Preamble_len
290 ! Set preamble length in frames
300 OUTPUT Testset;"CALL:APAR:PROBE:IADJUST ";Prb_ini_adj
310 ! Set Probe Initial Adjust
320 OUTPUT Testset;"CALL:APAR:PROBE:STEP:COUNT ";Prb_num_step
330 ! Set Probe Num Steps
340 OUTPUT Testset;"CALL:APAR:PROBE:SEQUENCE ";Prb_seq_max
350 ! Set Probe Sequence Max
360 ! This must be done BEFORE call limit mode is turned on
370 OUTPUT Testset;"CALL:APAR:PROBE:POWER:STEP ";Prb_pwr_step
380 ! Set Probe Power Step
390 !
400 !***Set up measurement parameters***
410 OUTPUT Testset;"SETUP:GAPP:TIMEOUT 60"
420 ! Set access probe power timeout to 60 seconds
430 !     
440 !***Set test conditions***
450 OUTPUT Testset;"CALL:CONNECTED:LIMIT:STATE 1"
460 ! Turn on call limit mode so connection is not established
470 ! This must be done after probe sequence max is set
480 !     
490 !***Obtain measurement results***
500 !      
510 DIM Access_probe(20)
520 DIM Gapp_meas$[500]
530 !
540 !***Test 1***
550 OUTPUT Testset;"CALL:POW ";Ior1
560 ! Set cell power for test 1
570 WAIT .1   ! Settling time for access terminal output power to slew
580 OUTPUT Testset;"CALL:FUNCTION:DATA:START"
590 ! Page access terminal
600 OUTPUT Testset;"READ:GAPP?"
610 ! Read power results for up to 20 access probes. If more than 20 access
620 ! probes measured, use the command, READ:GAPP:RANG60?
630 ENTER Testset;Gapp_meas$
640 OUTPUT Testset;"CALL:FUNCTION:DATA:STOP"
650 ! Stop data connection paging before repaging at next level
660 CLEAR SCREEN
670 PRINT "************************************************"
680 PRINT "*Range of Open Loop Output Power Test 1 Results*"
690 PRINT "************************************************"
700 GOSUB Print_result
710 !
720 !***Test 2***
730 !
740 OUTPUT Testset;"CALL:POW ";Ior2
750 ! Set cell power for test 2
760 WAIT .1
770 ! Settling time for mobile output power to slew
780 OUTPUT Testset;"CALL:FUNCTION:DATA:START"
790 ! Page access terminal
800 OUTPUT Testset;"READ:GAPP?"
810 ! Read access probe power
820 ENTER Testset;Gapp_meas$
830 OUTPUT Testset;"CALL:FUNCTION:DATA:STOP"
840 ! Stop data connection paging before repaging at next level
850 PRINT "************************************************"
860 PRINT "*Range of Open Loop Output Power Test 2 Results*"
870 PRINT "************************************************"
880 GOSUB Print_result
890 !   
900 !***Test 3***
910 !
920 OUTPUT Testset;"CALL:POW ";Ior3
930 ! Set cell power for test 3
940 WAIT .1
950 ! Settling time for mobile output power to slew
960 OUTPUT Testset;"CALL:FUNCTION:DATA:START"
970 ! Page access terminal
980 OUTPUT Testset;"READ:GAPP?"
990 ! Read access probe power
1000 ENTER Testset;Gapp_meas$
1010 !OUTPUT Testset;"CALL:FUNCTION:DATA:STOP"
1020 ! Stop data connection paging
1030 PRINT "************************************************"
1040 PRINT "*Range of Open Loop Output Power Test 3 Results*"
1050 PRINT "************************************************"
1060 GOSUB Print_result
1070 !
1080 PRINT
1090 PRINT "All Tests Complete!"
1100 PRINT
1110 !                 
1120 GOTO End_program
1130 !
1140 !*************
1150 !Sub Prgrams:*
1160 !*************
1170 !
1180  Print_result:!
1190 !
1200 !***Print measurement results sub-program***
1210 !
1220   Separator$=","!GAPP measurements are returned in a comma-separated string
1230   First_acc_probe=POS(Gapp_meas$,Separator$)
1240   !Find the first comma, which separates the integrity indicator from the
1250   !first access probe measurement
1260   Integrity=VAL(Gapp_meas$[1;First_acc_probe-1])
1270   !Convert the ascii integrity characters to a numeric value
1280       PRINT "Integrity Indicator = ";Integrity
1290       FOR I=1 TO Total_probes
1300         Acc_probe_mkr=First_acc_probe+((I-1)*17)
1310         !Set up a marker that will jump to each comma in the ascii string
1320         Access_probe(I)=VAL(Gapp_meas$[Acc_probe_mkr+1;Acc_probe_mkr+16])
1330         !Convert ascii to a numeric value
1340         PRINT "Access probe ";I-1;" measurement is ";Access_probe(I);" dBm/1.23 MHz"
1350       NEXT I
1360       DISP "Test complete"
1370   RETURN
1380 !
1390  End_program:!
1400 !
1410  !***Post test clean up***
1420  !     
1430   OUTPUT Testset;"CALL:CONNECTED:LIMIT:STATE 0"
1440   ! Turn off call limit mode
1450   ! Must do BEFORE can change probe max sequence
1460   OUTPUT Testset;"CALL:POW -55"
1470   ! Set Cell Power to default. Do this before reconfiguring other parms
1480   ! so signaling is successful (don't want cell power too low for signaling)
1490   OUTPUT Testset;"CALL:APAR:PREAMBLE:LENGTH 7"
1500   ! Set preamble length in frames
1510   OUTPUT Testset;"CALL:APAR:PROBE:IADJUST 0"
1520   ! Set Probe Initial Adjust
1530   OUTPUT Testset;"CALL:APAR:PROBE:STEP:COUNT 3"
1540   ! Set Probe Num Steps
1550   OUTPUT Testset;"CALL:APAR:PROBE:SEQUENCE 1"
1560   ! Set Probe Sequence Max
1570   OUTPUT Testset;"CALL:APAR:PROBE:POWER:STEP 3"
1580   ! Set Probe Step
1590   OUTPUT Testset;"INIT:GAPP:OFF"
1600   ! Set access probe power meas off
1610   DISP ""
1620 END

Related Topics

Manual Operation: Measuring Graphical Access Probe Power

Graphical Access Probe Power Measurement Description

Graphical Access Probe Power Troubleshooting