Programming a Graphical Access Probe Power Measurement

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\gapp.txt"
20    !This program measures a graphical access probe power sequence
30    !See "Access Probe Output Power" in TIA/EIA-98-D for specifications and standards
40    A=714
50    OUTPUT A;"*CLS"
60    CLEAR SCREEN
70    !***Specify call parameters***
80    Systype$="DIGITAL2000"
90    Band$="USPCS"
100   Channel=525
110   Sid=331
120   Nid=1
130   Radio_config$="F3R3"
140   Service_opt$="SO2"
150   !
160   !***Specify test parameters***
170   Loss_frequency$="836 MHZ,881 MHZ"
180   Expected_loss$="-2,-2"
190   Acc_prb_steps=8
200   Acc_prb_size=1
210   Max_resp_seq=1
220   Ior=-55
230   Pilot=-7
240   Paging_ch=-12
250   Sync=-16
260   Traffic=-15.5
270   !
280   !***Set up bus and measurement timeouts***
290   ON TIMEOUT 7,20 CALL Timeout
300   OUTPUT A;"SETUP:GAPP:TIMEOUT:STIME 30 S"
310   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON"
320   !
330   !***Return test set to IDLE call processing state***
340   OUTPUT A;"CALL:STATUS?"
350   ENTER A;Call_status$
360   IF Call_status$="IDLE" THEN GOTO 400
370   OUTPUT 714;"CALL:END"
380   WAIT 2
390   !
400   !***Set up path loss***
410   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$
420   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$
430   !
440   !***Set up access/paging parameters***
450   OUTPUT A;"CALL:OPER:MODE CALL" !Active cell  operating mode
460   OUTPUT A;"CALL:BAND ";Band$
470   OUTPUT A;"CALL:CHAN ";Channel
480   OUTPUT A;"CALL:POW ";Ior
490   OUTPUT A;"CALL:SID ";Sid
500   OUTPUT A;"CALL:NID ";Nid
510   OUTPUT A;"CALL:RCON ";Radio_config$
520   OUTPUT A;"CALL:PROT PREV6"
530   OUTPUT A;"CALL:PAG ";Paging_ch
540   OUTPUT A;"CALL:PAG:DRAT FULL"
550   OUTPUT A;"CALL:PIL ";Pilot
560   OUTPUT A;"CALL:SYNC ";Sync
570   OUTPUT A;"CALL:FCH ";Traffic
580   !
590   PRINT "Press continue when the mobile station has found service and registered"
600   PAUSE
610   CLEAR SCREEN
620   !
630   !***Turn call limit on***
640   OUTPUT A;"CALL:CONNECTED:LIMIT 1"
650   !
660   !***Set up measurement parameters***
670   OUTPUT A;"CALL:APARAMETER:POWER:STEP ";Acc_prb_size     !Power Step
680   OUTPUT A;"CALL:APARAMETER:POWER:STEP:COUNT ";Acc_prb_steps !Number of Steps
690   OUTPUT A;"CALL:APARAMETER:SEQUENCE:RESPONSE ";Max_resp_seq !Maximum response
700                                                              !sequence
710   !
720   !***Turn off timer-based registrations***
730   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF"
740   PRINT "WAITING FOR REGISTRATIONS TO COMPLETE"
750   WAIT 3
751   CLEAR SCREEN
760   !
770   !***Initiate the Graphical Access Probe Power measurement***
780   OUTPUT A;"INIT:GAPP"
790   PRINT "GAPP MEASUREMENT INITIATED"
800   !
810   !***Page the mobile station***
820   DISP "Paging mobile station..."
830   OUTPUT A;"CALL:ORIG"
840   DISP "Measuring Graphical Access Probe Power"
850   !
860   !***Check measurement progress indicator***
870   Total_probes=(Acc_prb_steps+1)*Max_resp_seq
880   PRINT "Total number of expected access probes = ";Total_probes
890   LOOP
900     OUTPUT A;"FETCH:GAPP:ICOUNT?"
910     ENTER A;Prog_ind
920     DISP "Received access probe ";Prog_ind;" of";Total_probes
930     WAIT .25
940   EXIT IF Prog_ind=Total_probes
950   END LOOP
960   !
970   !***Query measurement results***
980   DIM Access_probe(20)
990   DIM Gapp_meas$[500]
1000  OUTPUT A;"FETCH:GAPP?"
1010  ENTER A;Gapp_meas$
1020  Separator$="," !GAPP measurements are returned in a comma-separated string
1030  First_acc_probe=POS(Gapp_meas$,Separator$) !Find the first comma, which separates
1040                                             !the integrity indicator from the
1050                                             !first access probe measurement
1060  Integrity=VAL(Gapp_meas$[1;First_acc_probe-1]) !Convert the ascii integrity
1070                                                 !characters to a numeric value
1080  PRINT "Integrity Indicator = ";Integrity
1090  FOR I=1 TO Total_probes
1100    Acc_probe_mkr=First_acc_probe+((I-1)*17) !Set up a marker that will jump
1110                                             !to each comma in the ascii string
1120    Access_probe(I)=VAL(Gapp_meas$[Acc_probe_mkr+1;Acc_probe_mkr+16]) !Convert
1130                                             !ascii to a numeric value
1140    PRINT "Access probe ";I-1;" measurement is ";Access_probe(I);" dBm/1.23 MHz"
1150  NEXT I
1160  DISP "Test complete"
1170  !
1180  !***Return to default call processing states***
1190! OUTPUT A;"CALL:END"
1200 !OUTPUT A;"CALL:CONNECTED:LIMIT 0"
1210 !OUTPUT A;"CALL:REGISTER:TIMER:STATE ON"
1220  END
1230  !
1240 Timeout: SUB Timeout
1250    PRINT "Program timed out"
1260    CLEAR 7
1270    CLEAR 714
1280  SUBEND

Related Topics

Graphical Access Probe Power Measurement Description

Graphical Access Probe Power Troubleshooting