Programming a Code Channel Time/Phase Measurement

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\code_chan.txt"
20    !This program measures handoff waveform quality
30    !Refer to "Reverse Pilot Channel to Code Channel Time Tolerance" and
40    !"Reverse Pilot Channel to Code Channel Time Tolerance" for standards and specifications
50    CLEAR SCREEN
60    A=714
70    !***Specify call parameters***
80    Systype$="DIGITAL2000" !Cell System Type must be DIGITAL2000
90    Band$="USCELLULAR" !Cell band
100   Channel=384 !RF Channel
110   Sid=1 !System Identification
120   Nid=1 !Network Identification
130   Radio_config$="F3R3" !for code channel time/phase error, radio configuration must be
F3R3, F4R3, or F5R4
140   !
150   !***Specify test parameters***
160   Loss_frequency$="851 MHZ,896 MHZ" !Reverse channel, forward channel frequencies for
amplitude offset (path loss)
170   Expected_loss$="-2,-2" !Path loss at reverse channel, forward channel frequencies
180   !
190   ON TIMEOUT 7,20 CALL Timeout ! Calls "Timeout" routine
200   OUTPUT A;"SETUP:CCTPhase:TIMEOUT:STIME 10 S" !Sets waveform quality measurement timeout
to 10 seconds
210   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON"!Turns debug state on
220   !
230   !***Set up call parameters***
240   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
250   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
260   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell Band for selected System Type
270   OUTPUT A;"CALL:CHAN ";Channel !Sets RF Channel for selected System Type and Cell Band
280   OUTPUT A;"CALL:POW -50" !Sets and turns on Cell Power
290   OUTPUT A;"CALL:SID ";Sid! Sets System Identification
300   OUTPUT A;"CALL:NID ";Nid! Sets Network Identification
310   OUTPUT A;"CALL:RCON ";Radio_config$!Sets Radio configuration
320   OUTPUT A;"CALL:PROT PREV6" !Sets Protocol Revision for the selected System Type
330   !
340   PRINT "Turn on mobile station...press continue when it has found service and registered"
350   PAUSE
360   CLEAR SCREEN
370   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF" !Turns off timer-based registrations
380   WAIT 2 ! Waits for any timer-based registrations to clear out
390   !
400   !***Page the mobile station***
410   DISP "Paging mobile station..."
430   OUTPUT A;"CALL:ORIG" !Pages the mobile station
440   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state...hangs until state
change detector is disarmed
450   ENTER A;Call_connected
460   IF NOT Call_connected THEN
470     DISP "Call attempt failed"
480     STOP
490   ELSE
500     DISP "Call connected"
510   END IF
520   !
530   !***Set up measurement parameters***
540   OUTPUT A;"SETUP:CCTPhase:CONTINUOUS OFF" !Sets trigger arm state to single
550   OUTPUT A;"SETUP:CCTPhase:TERROR:LIMit 10ns" !Sets the time error pass/fail limit to 10
ns
560   OUTPUT A;"SETUP:CCTPhase:PERRor:LIMit 0.15rad" !Sets the phase error pass/fail limit to
0.15 radians
570   !
580   !***Obtain and display code channel time/phase pass/fail results***
590   WAIT 1
600   OUTPUT A;"INITIATE:CCTPhase" !Initiates a code channel time/phase error measurement
610   OUTPUT A;"FETCh:CCTPhase?" !Queries the test set for waveform quality measurement
results
620   ENTER A;Integrity,Time_err,Phase_err
630   PRINT "Integrity indicator = ";Integrity
640   IF Time_err THEN
650     PRINT "Time error test failed"
660   ELSE
670     PRINT "Time error test passed"
680   END IF
690   IF Phase_err THEN
700     PRINT "Phase error test failed"
710   ELSE
720     PRINT "Phase error test passed"
730   END IF
740   !
750   DISP "Test complete"
760   !
770   !***Return to idle call processing state***
780   OUTPUT A;"CALL:END"
790   END
800 Timeout: SUB Timeout     ! Global timeout handler (from Step 1)
810     PRINT "Program timed out"
820     CLEAR 7
830     CLEAR 714
840   SUBEND

Related Topics

Code Channel Time/Phase Error Measurement Description

Measuring Code Channel Time/Phase Error

Code Channel Time/Phase Error Measurement Troubleshooting

Control Program Example

SETup:CCTPhase

FETCh:CCTPhase

INITiate

READ

ABORt