Programming a Channel Power Measurement

Last updated: October 28, 2004

This section provides an example of how to make a channel power measurement via GPIB.

The following program example assumes that the mobile station's antenna output is connected to the RF IN/OUT connector, and the mobile station has found service.

For information on configuring the test set for a call, see Step 4: Make a connection .

The basic procedure to measure channel power is as follows:

Make a call.
Configure the channel power setup parameters using the SETup:CPOWer subsystem.
Use open and/or closed loop power control to set the mobile station power level.
Start the channel power measurement using the INITiate subsystem.
Use the FETCh:CPOWer command to obtain the measurement results.

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\chan_pwr.txt"
20    !This program measures Channel Power
30    !Refer to "Minimum Controlled Output Power" in TIA/EIA-98-D for standards and
specifications
40    CLEAR SCREEN
50    A=714
60    !
70    !***Specify call parameters***
80    Systype$="DIGITAL2000" !Cell system type
90    Band$="USCELLULAR" !Cell band
100   Channel=384 !RF channel
110   Sid=1 !System Identification
120   Nid=1 !Network Identification
130   Radio_config$="F3R3" !Radio configuration
140   Service_opt$="SO2" !Service Option
150   !
160   !***Specify test parameters***
170   Loss_frequency$="836 MHZ,881 MHZ" !Reverse channel, forward channel frequencies for
amplitude offset (path loss)
180   Expected_loss$="-3,-3" !Path loss at reverse channel, forward channel frequencies
190   Ior=-25 !Cell Power
200   Pilot=-7 !Pilot channel power level
210   Traffic=-7.4 !Traffic channel power level
220   !
230   ON TIMEOUT 7,20 CALL Timeout !Calls "Timeout" routine
240   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON" !Turns GPIB debug state on
250   OUTPUT A;"SETUP:CPOWER:TIMEOUT:STIME 10 S" !Sets channel power timeout to 10 seconds
260   !
270   !***Set up path loss***
280   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$ !Enters frequencies in
Amplitude Offset table
290   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$       !Enters loss values in
Amplitude Offset table
300   !
310   !***Set up call parameters***
320   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
330   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
340   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell band for selected System Type
350   OUTPUT A;"CALL:CHANNEL ";Channel !Sets Channel for selected System Type and Cell Band
360   OUTPUT A;"CALL:POW -50" ! Sets and turns on Cell Power for selected System Type
370   OUTPUT A;"CALL:SID ";Sid ! Sets System Identification
380   OUTPUT A;"CALL:NID ";Nid !Sets Network Identification
390   OUTPUT A;"CALL:RCON ";Radio_config$ !Sets Radio Configuration
400   OUTPUT A;"CALL:SOPTION ";Service_opt$ !Sets service option for the selected System Type
and Radio Configuration
410   OUTPUT A;"CALL:PROT PREV6" !Sets Protocol Revision for the selected System Type
420   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets F-Paging data rate to full rate
430   OUTPUT A;"CALL:PIL -7"   !Sets pilot to default
440   OUTPUT A;"CALL:SYNC -16" !Sets sync to default
450   OUTPUT A;"CALL:PAG -12"  !Sets paging to default
460   OUTPUT A;"CALL:FCH -15.6"!Sets traffic to default
470   !
480   PRINT "Turn on mobile station...press continue when it has found service and registered"
490   PAUSE
500   CLEAR SCREEN
510   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF" !turns off timer-based registration
520   WAIT 2 !Waits 2 seconds for any timer-based registrations in progress to complete
530   !
540   !***Page the mobile station***
550   DISP "Paging mobile station..."
560   OUTPUT A;"CALL:ORIG" !Pages the mobile station
570   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state...hangs until state
change detector is disarmed
580   ENTER A;Call_connected
590   IF NOT Call_connected THEN
600     DISP "Call attempt failed"
610     STOP
620   ELSE
630     DISP "Call connected"
640   END IF
650   !
660   !***Set up measurement parameters***
670   OUTPUT A;"SETUP:CPOWER:CONTINUOUS OFF" !Sets trigger arm state to single
680   OUTPUT A;"CALL:CONNECTED:DROP:TIMER:STATE 0" !Turns off call drop timer
690   OUTPUT A;"CALL:POW ";Ior !Sets and turns on Cell Power for selected System Type
700   OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE DOWN" !Starts transmission of All Down (1) power
control bits
710   OUTPUT A;"CALL:PIL ";Pilot !Sets pilot channel level
720   OUTPUT A;"CALL:FCH ";Traffic !Sets traffic channel level
730   !
740   !***Obtain measurement results***
750   WAIT 1 !Settling time
760   OUTPUT A;"INITIATE:CPOWER" !Initiates a channel power measurement
820   OUTPUT A;"FETCh:CPOWER?"
830   ENTER A;Integrity,Channel_power
840   DISP "Test complete"
850   !
860   !***Display measurement results
870   PRINT "Integrity indicator = ";Integrity
880   PRINT "Minimum power = ";Channel_power;" dBm/1.23 MHz"
890   !
900   !***Return to default call processing states***
910   OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE ACTIVE" !Returns to active power control bits
920   OUTPUT A;"CALL:CONNECTED:DROP:TIMER:STATE 1" !Returns call drop timer to ON
930   OUTPUT A;"CALL:REGISTER:TIMER:STATE ON" !Returns timer-based registration to ON
940   OUTPUT A;"CALL:POW -50" ! Returns cell power to -50 dBm/1.23 MHz
950   !
960   DISP "Test complete"
970   OUTPUT A;"CALL:END" !Ends the call
980   END
990 Timeout: SUB Timeout     ! Global timeout handler
1000    PRINT "Program timed out"
1010    CLEAR 7
1020    CLEAR 714
1030  SUBEND

Returned Values

This query returns an integrity indicator followed by a channel power measurement result (if results are available).

Programming a Channel Power Measurement

Programming Example

Returned Values

Related Topics