Programming a Tx Spurious Emissions Measurement

Last updated: October 28, 2004

This section provides an example of how to make transmitter spurious emissions measurements via GPIB.

The following program example assumes that the mobile station's antenna output is connected to the RF IN/OUT connector, and the mobile station has found service.

The basic procedure to measure spurious emissions remotely is:

Turn on the mobile station and perform a registration (wait for power-on or send CALL:REGister[:IMMediate] ).
Turn off timer-based registrations (see CALL:REGister:TIMer:STATe ).
Set up nominal power, initial power, step size, number of steps, and the maximum number of access probes for responses ( see CALL:APARameter ).
Set the trigger arm state to single (see SETup:CTXSpurious:CONTinuous ).
Perform a page or mobile station originated call.

Initiate the spurious emissions measurement using the INITiate<:measurement mnemonic>[:ON] . The <measurement mnemonic> for the cdma2000 transmitter spurious emissions measurement is CTXS.
Use the FETCh:CTXSpurious[:ALL]? command to obtain the measurement results.

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\tx_spurious.txt"
20    !This program measures conducted spurious emissions from the mobile station
30    !See "Conducted Spurious Emissions" in TIA/EIA-98-D for specifications and standards
40    CLEAR SCREEN
50    A=714
60    !***Specify call parameters***
70    Systype$="DIGITAL2000"
80    Band$="USCELLULAR"
90    Channel=384
100   Sid=1
110   Nid=1
120   Radio_config$="F3R3" !The test standard requires measurements at each radio config
130   Service_opt$="SO2"
140   !
150   !***Specify test parameters***
160   Loss_frequency$="836 MHZ,881 MHZ"
170   Expected_loss$="-2,-2"
180   Nom_pwr=7
190   Init_pwr=15
200   Acc_prb_steps=7
210   Num_step=7
220   Max_rsp_seq=15
230   Acc_prb_size=4
240   Ior=-90
250   Pilot=-7.4
260   Paging_ch=-12
270   Sync=-16
280   Traffic=-15.5
290   !
300   ON TIMEOUT 7,20 CALL Timeout
310   OUTPUT A;"SETUP:CTXSpurious:TIMEOUT:STIME 3 S"
320   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON"
330   !
340   !***Set up path loss***
350   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$
360   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$
370   !
380   !***Set up access/paging parameters***
390   OUTPUT A;"CALL:OPER:MODE CALL"
400   OUTPUT A;"CALL:BAND ";Band$
410   OUTPUT A;"CALL:CHAN ";Channel
420   OUTPUT A;"CALL:POW -50"
430   OUTPUT A;"CALL:SID ";Sid
440   OUTPUT A;"CALL:NID ";Nid
450   OUTPUT A;"CALL:RCON ";Radio_config$
460   OUTPUT A;"CALL:SOPTION ";Service_opt$
470   OUTPUT A;"CALL:PROT PREV6"
480   OUTPUT A;"CALL:PAG ";Paging_ch
490   OUTPUT A;"CALL:PAG:DRAT FULL"
500   OUTPUT A;"CALL:PIL ";Pilot
510   OUTPUT A;"CALL:SYNC ";Sync
520   OUTPUT A;"CALL:FCH ";Traffic
530   !
540   PRINT "Turn on mobile station...press continue when it has found service and registered"
550   PAUSE
560   CLEAR SCREEN
570   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF"
580   WAIT 2
590   !
600   !***Set up measurement parameters***
610   OUTPUT A;"SETUP:CTXSpurious:CONTINUOUS OFF"
620   OUTPUT A;"CALL:APAR:POW:NOM ";Nom_pwr
630   OUTPUT A;"CALL:APAR:POW:INIT ";Init_pwr
640   OUTPUT A;"CALL:APARAMETER:POWER:STEP ";Acc_prb_size
650   OUTPUT A;"CALL:APAR:POW:STEP:COUNT ";Num_step
660   OUTPUT A;"CALL:APARAMETER:POWER:STEP:COUNT ";Acc_prb_steps
670   OUTPUT A;"CALL:APAR:SEQ:RESP:MAX ";Max_rsp_seq
680   !
690   !***Make a call***
700   DISP "Paging mobile station..."
710   OUTPUT A;"CALL:ORIG"
720   OUTPUT A;"CALL:CONNECTED:STATE?"
730   ENTER A;Call_connected
740   IF NOT Call_connected THEN
750     DISP "Call attempt failed"
760     STOP
770   ELSE
780     DISP "Call connected"
790   END IF
800   !
810   !***Send all up power control bits***
820   OUTPUT A;"CALL:CLPC:REVERSE:MODE UP"
821   !
830   DISP "Measuring Tx Spurious Emissions"
840   !
850   !***Obtain measurement results***
860   OUTPUT A;"INITIATE:CTXSpurious"
870   OUTPUT A;"FETCH:CTXSpurious?"
880   ENTER A;Integ,Passfail,Lower_adj,Upper_adj,Lower_alt,Upper_alt
890   PRINT "Integrity indicator = ";Integ
900   IF Passfail THEN
910     PRINT "Test failed"
920   ELSE
930     PRINT "Test passed"
940   END IF
960   PRINT "Lower adjacent channel power = ";Lower_adj
970   PRINT "Upper adjacent channel power = ";Upper_adj
980   PRINT "Lower alternate power = ";Lower_adj
990   PRINT "Upper alternate power = ";Upper_adj
1000  DISP "Test complete"
1010  !
1020  !***Return to default call processing states***
1030  OUTPUT A;"CALL:CLPC:REVERSE:MODE ACTIVE" !Returns to active power control bits
1040  OUTPUT A;"CALL:END"
1050  OUTPUT A;"CALL:REGISTER:TIMER:STATE ON"
1060  END
1070  !
1080 Timeout: SUB Timeout
1090    PRINT "Program timed out"
1100    CLEAR 7
1110    CLEAR 714
1120  SUBEND

Returned Values

This query returns an integrity indicator followed by a channel power measurement result (if results are available).

Programming a Tx Spurious Emissions Measurement

Programming Example

Returned Values

Related Topics