Programming a Digital Average Power Measurement

 Last updated: October 28, 2004

 This section provides an example of how to make a digital average power measurement via GPIB.

 The following program example assumes that the mobile station's antenna output is connected to the RF IN/OUT connector, and the mobile station has found service.

 For information on configuring the test set for a call, see Step 4: Make a connection .

 The basic procedure to measure digital average power is as follows:

  1.  
  2. Make a call.
  3.  Configure the digital average power setup parameters using the SETup:DAPower subsystem.
  4.  Start the digital average power measurement using the INITiate subsystem.
  5.  Use the FETCh:DAPower command to obtain the measurement results.
 

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\avg_pwr.txt"
20    !This program measures average power
30    !Refer to "Maximum RF Output Power" in TIA/EIA-98-D for standards and specifications
40    CLEAR SCREEN
50    A=714
60    !
70    !***Specify call parameters***
80    Systype$="DIGITAL2000" !Cell System Type
90    Band$="USCellular" !Cell band
100   Channel=384 !RF channel
110   Sid=1 !System Identification
120   Nid=1 !Network Identification
130   Radio_config$="F3R3" !Radio Configuration
140   Service_opt$="SO2" !Service Option
150   !
160   !***Specify test parameters***
170   Loss_frequency$="836 MHZ,881 MHZ" !Reverse channel, forward channel frequencies for
amplitude offset (path loss)
180   Expected_loss$="-1,-1" !Path loss at reverse channel, forward channel frequencies
190   Ior=-104 !Cell Power
200   Pilot=-7 !Pilot channel power level
210   Traffic=-7.4 !Traffic channel power level
220   !
230   ON TIMEOUT 7,20 CALL Timeout ! Calls "Timeout" routine
240   OUTPUT A;"SETUP:DAPOWER:TIMEOUT:STIME 10 S" !***Sets average power measurement timeout to 10 seconds***
250   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON"!***Turn debug state on***
260   !
270   !***Set up path loss***
280   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$ !Enters frequencies in Amplitude Offset table
290   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$ !Enters loss values in Amplitude
Offset table
300   !
310   !***Set up call parameters***
320   OUTPUT A;"CALL:OPER:MODE CALL" !***Sets Operating Mode to Active Cell***
330   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
340   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell band for selected System Type
350   OUTPUT A;"CALL:CHAN ";Channel !Sets Channel for selected System Type and Cell Band
360   OUTPUT A;"CALL:POW -50" ! Sets and turns on Cell Power for selected System Type
370   OUTPUT A;"CALL:SID ";Sid ! Sets System Identification
380   OUTPUT A;"CALL:NID ";Nid ! Sets Network Identification
390   OUTPUT A;"CALL:RCON ";Radio_config$ !Sets Radio configuration
400   OUTPUT A;"CALL:SOPTION ";Service_opt$ !Sets service option for the selected System Type
and Radio Configuration
410   OUTPUT A;"CALL:PROT:DIG2000 PREV6" ! Sets Protocol Revision for the selected System Type
420   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets F-Paging data rate to full rate
430   OUTPUT A;"CALL:PIL -7"   !Sets pilot to default
440   OUTPUT A;"CALL:SYNC -16" !Sets sync to default
450   OUTPUT A;"CALL:PAG -12"  !Sets paging to default
460   OUTPUT A;"CALL:FCH -15.6"!Sets traffic to default
470   !
480   PRINT "Turn on mobile station...press continue when it has found service and registered"
490   PAUSE
500   CLEAR SCREEN
510   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF" !Turns timer-based registration off
520   WAIT 2 !Waits 2 seconds for timer-based registrations in progress to clear out
530   !
540   !***Page the mobile station***
550   DISP "Paging mobile station..."
560   OUTPUT A;"CALL:ORIG" !Pages the mobile station
570   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state...hangs until state
change detector is disarmed
580   ENTER A;Call_connected
590   IF NOT Call_connected THEN
600     DISP "Call attempt failed"
610     STOP
620   ELSE
630     DISP "Call connected"
640   END IF
650   !
660   !***Set up measurement parameters***
670   OUTPUT A;"SETUP:DAPOWER:CONTINUOUS OFF" !Sets trigger arm state to single
680   OUTPUT A;"CALL:POW ";Ior !Sets Cell Power for the selected System Type
690   OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE UP" !Starts transmission of All Up (0) power
control bits
700   OUTPUT A;"CALL:PIL ";Pilot !Sets pilot channel level
710   OUTPUT A;"CALL:FCH ";Traffic !Sets traffic channel level
720   !
730   !***Obtain measurement results***
740   WAIT 1 !Settling time
750   OUTPUT A;"INITIATE:DAPOWER" !Initiates an Average Power measurement
810   OUTPUT A;"FETCh:DAPOWER?"
820   ENTER A;Integrity,Avg_power_dbm
830   Avg_power_dbw=Avg_power_dbm-30
840   !
850   !***Display measurements if the mobile station did not drop the call***
860   OUTPUT A;"CALL:STATUS?"
870   ENTER A;Call_status$
880   IF Call_status$="CONN" THEN
890     PRINT "Integrity indicator = ";Integrity
900     PRINT "Maximum power = ";Avg_power_dbm;"dBm";", ";Avg_power_dbw;"dBW"
910   ELSE
920     PRINT "Mobile station dropped call, invalid results"
930   END IF
940   !
950   !***Return to default call processing states***
960   OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE ACTIVE" ! Returns to active power control bits
970   OUTPUT A;"CALL:POW:DIG2000 -50" ! Returns cell power to -50 dBm/1.23 MHz
980   !
990   DISP "Test complete"
1000  OUTPUT A;"CALL:END"
1010  END
1020 Timeout: SUB Timeout
1030    PRINT "Program timed out"
1040    CLEAR 7
1050    CLEAR 714
1060  SUBEND
 

Returned Values

 This program returns an integrity indicator followed by a digital average power measurement result (if results are available).

 

Related Topics
 

Digital Average Power Measurement Description

 Measuring Digital Average Power

 Digital Average Power Troubleshooting

 Control Program Example

 CALibration Subsystem

 READ? Subsystem

 SETup:DAPower

 INITiate

 FETCh:DAPower