Programming a Gated Power Measurement

Last updated: October 28, 2004

This section provides an example of how to make a gated power measurement via GPIB.

The basic procedure to measure gated power is as follows:

Make a call using IS-95 or IS-2000 system type with F1R1 (radio configuration 1) or F2R2 (radio configuration 2). See CALL[:CELL]:RCONfig .
Select a loopback service option (SO2, SO9, or SO55) .
Select eighth rate data (see CALL[:CELL[1]]:TRAFfic[:FORWard]:DRATe ).
Configure the gated power measurement setup parameters using the SETup:GPOWer subsystem.
Start the waveform quality measurement using the INITiate subsystem.
Use the FETCh:GPOWer command to obtain gated power measurement results.

NOTE

Gated power measurement display trace data is available using the FETCh:GPOWer:TRACe? command.

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\gated_power.txt"
20    !This program measures gated power
30    !See "Standby Output Power and Gated Output Power" in TIA/EIA-98-D for specifications
and standards
40    CLEAR SCREEN
50    A=714
60    !***Specify call parameters***
70    Systype$="DIGITAL2000" !Cell System Type
80    Band$="USC" !Frequency Band
90    Channel=384 !RF Channel
100   Sid=1 !System Identification
110   Nid=1 !Network Identification
120   Radio_config$="F2R2" !Radio Configuration 1 or 2 is required for Gated Power
measurements
130   Service_opt$="SO9" !Service Option
150   !
160   !***Specify test parameters***
170   Loss_frequency$="1900 MHZ,1945 MHZ" !Reverse channel, forward channel frequencies for
amplitude offset (path loss)
180   Expected_loss$="-2,-2" !Path loss at reverse channel, forward channel frequencies
190   Ior=-75 !Cell power for gated power testing
200   Pilot=-7 !Pilot channel power level for gated power testing
210   Traffic=-7.4 !Traffic channel power level for gated power testing
220   Data_pnt=300
230   !
240   ON TIMEOUT 7,20 CALL Timeout ! Calls "Timeout" routine
250   OUTPUT A;"SETUP:CFER:TIMEOUT:STIME 10 S" !Sets FER measurement timeout to 10 seconds
260   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON" !Turns debug state on
270   !
280   !***Set up path loss***
290   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$ !Enters frequencies in
Amplitude Offset table
300   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$ !Enters loss values in Amplitude
Offset table
310   !
320   !***Set up call parameters***
330   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
340   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
350   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell Band for selected System Type
360   OUTPUT A;"CALL:CHAN ";Channel ! Sets Channel for selected System Type and Cell Band
370   OUTPUT A;"CALL:POWER -50" !Sets and turns on Cell Power for call setup
380   OUTPUT A;"CALL:SID ";Sid! Sets System Identification
390   OUTPUT A;"CALL:NID ";Nid! Sets Network Identification
400   OUTPUT A;"CALL:RCON ";Radio_config$ !Sets Radio Configuration
410   OUTPUT A;"CALL:SOPTION ";Service_opt$ !Sets service option for selected System Type and
Radio Configuration
420   OUTPUT A;"CALL:PROT PREV6" !Sets Protocol Revision for the selected System Type
430   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets Paging channel data rate to full rate
440   OUTPUT A;"CALL:TRAFFIC:DRATE EIGHTH" !Sets traffic/fundamental channel data rate to
eighth
450   OUTPUT A;"CALL:PIL -7"    !Sets Pilot to default
460   OUTPUT A;"CALL:SYNC -16"  !Sets Sync to default
470   OUTPUT A;"CALL:PAG -12"   !Sets Paging to default
480   OUTPUT A;"CALL:FCH -15.6" !Sets Traffic to default
490   !
500   PRINT "Turn on mobile station...press continue when it has found service and registered"
510   PAUSE
520   CLEAR SCREEN
530   OUTPUT A;"CALL:REG:TIMER:STATE OFF" !Turns timer-based registrations off
540   WAIT 2 !Waits 2 seconds for any timer-based registrations to clear out
550   !
560   !***Page the mobile station***
570   DISP "Paging mobile station..."
580   OUTPUT A;"CALL:ORIG" !Pages the mobile station
590   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state...hangs until state
change detector is disarmed
600   ENTER A;Call_connected
610   IF NOT Call_connected THEN
620     DISP "Call attempt failed"
630     STOP
640   ELSE
650     DISP "Call connected"
660   END IF
670   !
680   !***Set up measurement parameters***
690   OUTPUT A;"SETUP:GPOWER:CONTINUOUS OFF" !Sets trigger arm state to single
700   OUTPUT A;"CALL:POW ";Ior ! Sets Cell Power for gated power measurement
710   OUTPUT A;"CALL:PIL ";Pilot !Sets Pilot channel level
720   OUTPUT A;"CALL:FCH ";Traffic !Sets Traffic channel level
730   !
740   !***Obtain pass/fail measurement results***
750   OUTPUT A;"INITIATE:GPOWER" !Initiates a gated power measurement
760   DISP "Measuring gated power"
770   OUTPUT A;"FETCh:GPOWER?" !Queries the test set for gated power measurement results
780   DISP "Gated Power measurement completed"
790   ENTER A;Integrity,Passfail
800   SELECT Passfail !Assign pass/fail results to a string
810   CASE 0
820     Pass_fail$="PASSED"
830   CASE 1
840     Pass_fail$="FAILED"
850   END SELECT
860   PRINT "Integrity indicator = ";Integrity
870   PRINT "Gated power test results = ";Pass_fail$
880   !
990   OUTPUT A;"CALL:END" !Ends the call
1000  END
1010 Timeout: SUB Timeout    ! Global timeout handler
1020    PRINT "Program timed out"
1030    CLEAR 7
1040    CLEAR 714
1050  SUBEND

Programming a Gated Power Measurement

Programming Example

Related Topics