Agilent Technologies Home Page 8960 Series 10 Wireless Communications Test Set
- +
Home | Product Web Site | Contact Us
+
- -
+ -
8960 cdma2000 Online User's Guide
E1962B, E6702B
Search this guide for     
search tips


Feedback
Did the information on this web page help answer your question or solve a problem?

Yes
No
Did not apply

Please provide additional comments about this page.
(Optional, 255 character max)


Email address (optional):

Privacy Notice: We will not sell or give away your email address to any third party.

 

Programming a Handoff Waveform Quality Measurement

Last updated: October 28, 2004

This section provides an example of how to make a handoff waveform quality measurement via GPIB.

The following program example assumes that the mobile station's antenna output is connected to the RF IN/OUT connector, and the mobile station has found service.

The basic procedure to measure handoff waveform quality is as follows:

  1. Make a call using Radio Configuration 3 (F3R3) and above.
  2. Configure the handoff waveform quality measurement setup parameters using the SETup:HWQuality subsystem.
  3. Start the handoff waveform quality measurement using the INITiate subsystem.
  4. Use the FETCh:HWQuality command to obtain handoff waveform quality measurement results.

Programming Example

 
10    !This program measures handoff waveform quality
20    !Refer to "Waveform Quality and Frequency Accuracy" in EIA/TIA-IS-98D
30    !for standards and specifications
40    CLEAR SCREEN
50    A=714
60    !***Specify call parameters***
70    Systype$="DIGITAL2000" !Cell System Type
80    Band$="USCELLULAR" !Cell band
90    Channel=29 !RF Channel
100   Sid=2236 !System Identification
110   Nid=65535 !Network Identification
120   Radio_config$="F3R3" !For handoff waveform quality,
130                        !radio configuration must be F3R3 or F4R3
140   Service_opt$="SO2"   !Loopback service option
150   !
160   !***Specify test parameters***
170   !Reverse channel, forward channel
180   !frequencies for amplitude offset (path loss)
190   Loss_frequency$="851 MHZ,896 MHZ"
200   !
210   !Path loss at reverse channel, forward channel frequencies
220   Expected_loss$="-2,-2"
230   Ior=-50!Cell power
240   Pilot=-7 !Pilot channel power level
250   Traffic=-7.4 !Traffic channel power level
260   !
270   ON TIMEOUT 7,20 CALL Timeout ! Calls "Timeout" routine
280   !Sets waveform quality measurement timeout to 10 seconds
290   OUTPUT A;"SETUP:WQU:TIMEOUT:STIME 10 S"
300   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON"!Turns debug state on
310   !
320   !***Set up call parameters***
330   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
340   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
350   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell Band for selected System Type
360   !Sets RF Channel for selected System Type and Cell Band
370   OUTPUT A;"CALL:CHAN ";Channel
380   OUTPUT A;"CALL:POW -35" !Sets and turns on Cell Power
390   OUTPUT A;"CALL:SID ";Sid! Sets System Identification
400   OUTPUT A;"CALL:NID ";Nid! Sets Network Identification
410   OUTPUT A;"CALL:RCON ";Radio_config$!Sets Radio configuration
420   !Set service option for selected System Type and Radio Configuration
430   OUTPUT A;"CALL:SOPTION ";Service_opt$
440   !Sets Protocol Revision for the selected System Type
450   OUTPUT A;"CALL:PROT PREV6"
460   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets Paging data rate to full rate
470   OUTPUT A;"CALL:PIL -7"    !Sets pilot to default
480   OUTPUT A;"CALL:SYNC -16"  !Sets sync to default
490   OUTPUT A;"CALL:PAG -12"   !Sets paging to default
500   OUTPUT A;"CALL:FCH -15.6" !Sets traffic to default
510   !
520   PRINT "Turn on mobile station."
530   PRINT "Press continue when it has found service and registered"
540   PAUSE
550   CLEAR SCREEN
560   !Turn off timer-based registrations
570   OUTPUT A;"CALL:REGISTER:TIMER:STATE OFF"
580   WAIT 2 ! Waits for any timer-based registrations to clear out
590   !
600   !***Page the mobile station***
610   DISP "Paging mobile station..."
620   OUTPUT A;"CALL:ORIG" !Pages the mobile station
630   !Queries for connected/idle state.
640   !Hangs until state change detector is disarmed
650   OUTPUT A;"CALL:CONNECTED:STATE?"
660   ENTER A;Call_connected
670   IF NOT Call_connected THEN
680     DISP "Call attempt failed"
690     STOP
700   ELSE
710     DISP "Call connected"
720   END IF
730   !
740   !***Set up measurement parameters***
750   !Sets trigger arm state to single
760   OUTPUT A;"SETUP:WQUALITY:CONTINUOUS OFF"
770   !Sets Cell Power for the selected System Type
780   OUTPUT A;"CALL:POW ";Ior
790   !Alternating up/down power control bits
800   OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE ALT"
810   OUTPUT A;"CALL:PIL ";Pilot !Sets Pilot channel level
820   OUTPUT A;"CALL:FCH ";Traffic !Sets Fundamental (Traffic) channel level
830   OUTPUT A;"SETUP:WQUALITY:CDPOWER:IQINactive:LIMIT -23"
840   !
850   !***Obtain and display handoff waveform quality measurement results***
860   WAIT 1
870   OUTPUT A;"INITIATE:HWQUALITY" !Initiates a Waveform Quality measurement
880   !Queries the test set for waveform quality measurement results
890   OUTPUT A;"FETCh:HWQUALITY?"
900   ENTER A;Integrity,Rho,Freq_error,Time_error,Carr_feed,Phase_err,Mag_err
910   PRINT "Integrity indicator = ";Integrity
920   PRINT "Rho = ";Rho
930   PRINT "Frequency error = ";Freq_error
940   PRINT "Time error = ";Time_error
950   PRINT "Carrier feedthrough = ";Carr_feed
960   PRINT "Phase error = ";Phase_err
970   PRINT "Magnitude error = ";Mag_err
980   !
990   DISP "Test complete"
1000  !
1010  !***Return to default call processing settings***
1020  !Return to active power control bits
1030  OUTPUT A;"CALL:CLPCONTROL:REVERSE:MODE ACTIVE"
1040  OUTPUT A;"CALL:POW:DIG2000 -50"! Returns cell power to -50 dBm/1.23 MHz
1050  OUTPUT A;"CALL:END"
1060  END
1070 Timeout: SUB Timeout    ! Global timeout handler (from Step 1)
1080    PRINT "Program timed out"
1090    CLEAR 7
1100    CLEAR 714
1110  SUBEND

Top of pagetop of page     

+
Privacy Statement | Terms of Use | Webmaster  +  © Agilent 2000-2008
+