|
|
Programming a Multi-Tone Audio Measurement
Last updated: July 29, 2009
General Programming Procedure
-
Make the proper hardware connection.
-
Set up the call parameters and establish a voice call (such as SO1, SO17, or SO32769).
-
Set the Voice SO Mode to MULTitone for downlink test or NFRames for uplink test using
CALL[:CELL[1]]:FCHannel[:FORWard]:SOURce
(for IS-2000 system) or
CALL[:CELL[1]]:TRAFfic[:FORWard]:SOURce
(for IS-95 system).
-
Set up the measurement parameters as required (such as multi-tone audio measurement mode, multi-tone audio generator's frequencies/levels, etc.) using the
SETup:CMAudio
commands.
-
Initiate the multi-tone audio measurement using the
INITiate<:measurement mnemonic>[:ON]
. The <measurement mnemonic> for multi-tone audio measurements is CMAudio.
-
Use the
FETCh:CMAudio
commands to obtain the measurement results.
Programming Example for a Downlink Multi-Tone Audio Measurement
This example is to test the mobile station's speaker quality using the Multi-Tone Audio measurements in Downlink mode.
The following procedure assumes that the mobile station's antenna output is connected to the test set's front-panel RF IN/OUT connector. The analog audio from the mobile phone speaker is fed back to the test set's AUDIO IN port. The mobile station supports SO17 service option.
10 !The simple test executive allows you to do downlink multitone
measurement
20 !
36 COM Testset
37 !
40 Testset=714! Set "Testset" to equal GPIB address of 8960
41 !
42 CLEAR SCREEN
60 !
61 !**************************************************************
62 ! SET UP GPIB TIMEOUT
63 !**************************************************************
64 !
65 ON TIMEOUT 7,30 CALL Timeout! Calls "Timeout" routine
73 !
76 !**************************************************************
77 ! VARIABLE DECLARATIONS FOR CALL SET UP - MOBILE SPECIFIC
78 !**************************************************************
79 Systype$="DIGITAL2000"!Cell System Type
80 Band$="USPCs" !PCS band
81 Channel=525 !RF Channelfor call setup
82 Sid=2 !System Identification
84 Nid=1 !Network Identification
85 Radio_config$="F2R2"!Radio Configuration
86 Service_opt$="SO17"!Voice Service Option
87 !
138 !*************************************************************
139 ! Test Executive
140 !*************************************************************
141 !
142 GOSUB Preset_test_set
143 GOSUB Set_call_parms
146 GOSUB Register
151 GOSUB Connect
155 GOSUB Multitone_down
157 GOTO End_program!Jumps to end of program
222 !
223 !**************************************************************
224 ! PRESET TEST SET
225 !**************************************************************
226 Preset_test_set:!
227 !
228 PRINT "Reset 8960"
229 OUTPUT Testset;"*RST"!RESET TEST SET
230 OUTPUT Testset;"*OPC?"
231 ENTER Testset;Opc$
232 RETURN
233 !
247 !***************************************************************
253 ! SET UP CALL PARAMETERS
254 !***************************************************************
255 Set_call_parms:!
256 !
257 PRINT "Setup Network/Basestation Parameter"
270 OUTPUT Testset;"CALL:SYSTEM ";Systype$!Sets System Type
280 OUTPUT Testset;"CALL:BAND ";Band$
!Sets Cell Band for selected System Type
290 OUTPUT Testset;"CALL:CHAN ";Channel
!Sets RF Channel for selected System Type and Cell Band
300 OUTPUT Testset;"CALL:POW -55"!Sets and turns on Cell Power
310 OUTPUT Testset;"CALL:SID ";Sid!Sets System Identification
320 OUTPUT Testset;"CALL:NID ";Nid!Sets Network Identification
330 OUTPUT Testset;"CALL:CELL:RCONFIG ";Radio_config$
341 OUTPUT Testset;"CALL:SOPTION ";Service_opt$
!Sets service option for selected System Type
and Radio Configuration
350 OUTPUT Testset;"CALL:PAG:DRAT FULL"
!Sets Paging data rate to full rate
370 OUTPUT Testset;"CALL:PIL -7"!Sets pilot to default
380 OUTPUT Testset;"CALL:SYNC -16"!Sets sync to default
390 OUTPUT Testset;"CALL:PAG -12"!Sets paging to default
400 RETURN !Sub-routine return
420 !
434 !***************************************************************
435 ! REGISTER MOBILE
436 !***************************************************************
437 Register:!
438 !
439 PRINT "Pls. Power On MS, Then Press F2 Continue"
441 PAUSE
442 PRINT "Register MS on 8960"
443 OUTPUT Testset;"CALL:MS:REPORTED:CLEAR:ALL"
!Clear MS reported database
444 OUTPUT Testset;"CALL:REG"
445 Reg_timer=TIMEDATE
446 LOOP
448 OUTPUT Testset;"CALL:MS:REP:ESN:HEX?"
449 ENTER Testset;Esn$
450 Reg_time=TIMEDATE-Reg_timer
469 EXIT IF LEN(Esn$)>3 OR Reg_time>30
470 END LOOP
472 IF Reg_time>30 THEN
473 PRINT "Registration Timed Out, Check Phone Setup"
474 GOTO End_program
475 END IF
477 PRINT "Mobile Registration Complete"
478 PRINT
482 !
483 !**************************************************************
484 ! PRINT MOBILE REGISTRATION INFO
485 !**************************************************************
486 !
487 !Read registration information
488 !
489 OUTPUT Testset;"CALL:MS:REP:ESN:HEX?"
490 ENTER Testset;Esn$
491 OUTPUT Testset;"CALL:MS:REP:MCC?"
492 ENTER Testset;Mcc$
493 OUTPUT Testset;"CALL:MS:REP:MNC?"
494 ENTER Testset;Mnc$
495 OUTPUT Testset;"CALL:MS:REP:MSIN?"
496 ENTER Testset;Msin$
497 OUTPUT Testset;"CALL:MS:REP:BCLASS?"
498 ENTER Testset;Bclass$
499 OUTPUT Testset;"CALL:MS:REP:EIRP?"
500 ENTER Testset;Eirp$
501 OUTPUT Testset;"CALL:MS:REP:OPER:MODE?"
502 ENTER Testset;Opmode$
503 OUTPUT Testset;"CALL:MS:REP:PREV?"
504 ENTER Testset;Prev$
507 PRINT "Mobile Registration Information:"
508 PRINT
509 Print_res_str("Mobile ESN:",Esn$)
510 Print_res_str("Mobile MCC:",Mcc$)
511 Print_res_str("Mobile MNC:",Mnc$)
512 Print_res_str("Mobile MSIN:",Msin$)
513 Print_res_str("Mobile BAND CLASS:",Bclass$)
514 Print_res_str("Mobile EIRP:",Eirp$)
515 Print_res_str("Mobile OP MODE:",Opmode$)
516 Print_res_str("Mobile P_REV:",Prev$)
518 PRINT
519 !
520 RETURN
522 !
703 !**************************************************************
704 ! CONNECT CALL
705 !**************************************************************
706 Connect:!
707 !
708 !***Page the mobile station***
709 !
710 Connect_tries=0
711 PRINT "Paging mobile station..."
714 LOOP
715 !
716 OUTPUT Testset;"CALL:ORIG"!Pages the mobile station
717 OUTPUT Testset;"CALL:CONNECTED:STATE?"
!Queries for connected/idle state
718 ENTER Testset;Call_connected
719 Connect_tries=Connect_tries+1
720 IF NOT Call_connected THEN
721 WAIT .2
723 END IF
724 EXIT IF Call_connected OR Connect_tries=50
!try 3 times to connect
725 END LOOP
726 IF NOT Call_connected THEN
727 PRINT "Call attempt failed"
728 GOTO End_program
729 ELSE
730 PRINT "Call connected"
731 Current_chan=Primary_channel
732 END IF
733 PRINT
736 RETURN
737 !
747 !*************************************************************
748 ! Multitone_down: Downlink Audio measurement mode is used to
749 ! test the analog signals presented at the AUDIO IN port of
750 ! the test set so that the connectivity and performance of
751 ! the analog signal handling components of the mobile
752 ! station(such as speaker, decoder, etc.) can be verified
752 !*************************************************************
753 Multitone_down:!
754 !
755 DIM Mta_lev$[1000]
!Define an arry to hold multitone measurement results
756 OUTPUT Testset;"CALL:FCHannel:SOURce MULTitone"
!Set up the Voice SO Mode required for the
downlink measurement.
757 !*** multi-tone audio measurement setup ***
758 !1. Set up audio generator parameters for downlink test
759 OUTPUT Testset;"SETup:CMAudio:GENerator:FREQuency:
DOWNlink:PRESet NARRow"!Set up downlink frequency
760 OUTPUT Testset;"SETup:CMAudio:GENerator:LEVel:
DOWNlink:ALL:TOTal 30"!Set up downlink level
761 !2. Set up audio analyzer parameters for downlink test.
762 OUTPUT Testset;"SETup:CMAudio:ANALyzer:FREQuency:all:
GENerator ON"!Set up audio analyzer frequency to on
763 !3. Set up multitone measurement limit lower/upper level
764 OUTPUT Testset;"SETup:CMAudio:LEVel:ALL:LIMit:LOWer -25,-25,
-25,-50,-50,-50,-75,-75,-75,-100,-100,-100,-100,-100,-75,
-75,-75,-50,-50,-50"
765 OUTPUT Testset;"SETup:CMAudio:LEVel:ALL:LIMit:UPPer 25,25,
25,50,50,50,75,75,75,100,100,100,100,100,75,75,75,50,50,
50"
766 !4. Set up multitone measurement
767 OUTPUT Testset;"SETup:CMAudio:COUNt 10"
!Set the Multi-Measurement Count to 10
768 OUTPUT Testset;"SETup:CMAudio:MEASurement:MODE DOWNlink"
!Set the Measurement Mode to Downlink Audio
769 OUTPUT Testset;"SETup:CMAudio:REFerence:MODE ABSolute"
!Set the Analyzer 0dB Reference Mode to Absolute
770 OUTPUT Testset;"SETup:CMAudio:REFerence:ABSolute:LEVel:
DOWNLINK 150 mV"
!Set the Analyzer Downlink Reference Level to 150 mV
771 OUTPUT Testset;"SETup:CMAudio:PEAK:VOLTage 800 mV"
!Set the Expected Audio In Peak Voltage to 800 mV
772 OUTPUT Testset;"SETup:CMAudio:CONTinuous OFF"
!Set the Trigger Arm to Single
773 !
774 !Measure downlink multitone
775 PRINT "MultiTone Audio Downlink Test Result"
776 OUTPUT Testset;"INITiate:CMAudio"
782 OUTPUT Testset;"FETCh:CMAudio:INTegrity?"
783 ENTER Testset;Integrity
784 OUTPUT Testset;"FETCh:CMAudio:LEVel?"
785 ENTER Testset;Mta_lev$
786 OUTPUT Testset;"FETCh:CMAudio:LEVel:LIMit:FAIL?"
787 ENTER Testset;Result
788 Print_results("Integrity indicator = ",Integrity,"")
789 FOR I=1 TO 20
790 Comma=1+(I-1)*17
791 Print_results("Tone "&VAL$(I),
VAL(Mta_lev$[Comma;16]),"dB")
792 NEXT I
793 PRINT "Downlink Multitone Test Result vs.
Lower/Upper Limit(0=Pass, 1=Fail): ";Result
794 RETURN
795 !
2120 !**************************************************************
2121 ! End of All Testing Cleanup
2122 !**************************************************************
2123 End_program:!
2124 !
2128 OUTPUT Testset;"CALL:END"
2129 PRINT "End of Program"
2138 END
2139 !
2140 !**************************************************************
2141 ! Sub-program Section
2142 !**************************************************************
2143 !
2144 Timeout: SUB Timeout! Global timeout handler (from Step 1)
2145 COM Testset
2146 PRINT "Program timed out"
2147 CLEAR 7
2148 CLEAR Testset
2149 STOP
2150 SUBEND
2151 !
2152 Print_results: SUB Print_results(Meas_name$,Res1,Units$)
2153 !
2154 PRINT USING "5X,50A,5X,M8D.4D,1X,15A";
Meas_name$;Res1;Units$
2155 !
2156 SUBEND
2157 !
2158 Print_res_str: SUB Print_res_str(String_name$,Results$)
2159 !
2160 PRINT USING "5X,30A,5X,20A";String_name$;Results$
2161 !
2162 SUBEND
2164
Programming Example for an Uplink Multi-Tone Audio Measurement
This example is to test the mobile station's microphone quality using the Multi-Tone Audio measurements in uplink mode.
The program example assumes that the mobile station's antenna output is connected to the test set's front-panel RF IN/OUT connector. The analog audio sent from AUDIO OUT port of the test set's front-panel is fed to the mobile phone's microphone. The mobile station supports SO17 service option.
10 !The simple test executive allows you to do uplink multitone
measurement
35 !
36 COM Testset
37 !
40 Testset=714! Set "Testset" to equal GPIB address of 8960
41 !
42 CLEAR SCREEN
60 OUTPUT Testset;"SYST:LOG:UI:GPIB:STAT ON"
61 !***************************************************************
62 ! SET UP GPIB TIMEOUT
63 !***************************************************************
64 !
65 ON TIMEOUT 7,30 CALL Timeout! Calls "Timeout" routine
73 !
76 !***************************************************************
77 ! VARIABLE DECLARATIONS FOR CALL SET UP - MOBILE SPECIFIC
78 !***************************************************************
79 Systype$="DIGITAL2000"!Cell System Type
80 Band$="USPCs"!PCS band
81 Channel=525!RF Channelfor call setup
82 Sid=2 !System Identification
84 Nid=1 !Network Identification
85 Radio_config$="F2R2"!Radio Configuration
86 Service_opt$="SO17"!Voice Service Option
87 !
138 !**************************************************************
139 ! Test Executive
140 !**************************************************************
141 !
142 GOSUB Preset_test_set
143 GOSUB Set_call_parms
146 GOSUB Register
151 GOSUB Connect
155 GOSUB Multitone_up
157 GOTO End_program!Jumps to end of program
222 !
223 !***************************************************************
224 ! PRESET TEST SET
225 !***************************************************************
226 Preset_test_set:!
227 !
228 PRINT "Reset 8960"
229 OUTPUT Testset;"*RST"!RESET TEST SET
230 OUTPUT Testset;"*OPC?"
231 ENTER Testset;Opc$
232 RETURN
233 !
247 !***************************************************************
253 ! SET UP CALL PARAMETERS
254 !***************************************************************
255 Set_call_parms:!
256 !
257 PRINT "Setup Network/Basestation Parameter"
270 OUTPUT Testset;"CALL:SYSTEM ";Systype$!Sets System Type
280 OUTPUT Testset;"CALL:BAND ";Band$
!Sets Cell Band for selected System Type
290 OUTPUT Testset;"CALL:CHAN ";Channel
!Sets RF Channel for selected System Type and Cell Band
300 OUTPUT Testset;"CALL:POW -55"!Sets and turns on Cell Power
310 OUTPUT Testset;"CALL:SID ";Sid!Sets System Identification
320 OUTPUT Testset;"CALL:NID ";Nid!Sets Network Identification
330 OUTPUT Testset;"CALL:CELL:RCONFIG ";Radio_config$
341 OUTPUT Testset;"CALL:SOPTION ";Service_opt$
!Sets service option for selected System Type and
Radio Configuration
350 OUTPUT Testset;"CALL:PAG:DRAT FULL"
!Sets Paging data rate to full rate
370 OUTPUT Testset;"CALL:PIL -7"!Sets pilot to default
380 OUTPUT Testset;"CALL:SYNC -16"!Sets sync to default
390 OUTPUT Testset;"CALL:PAG -12"!Sets paging to default
400 RETURN !Sub-routine return
420 !
434 !***************************************************************
435 ! REGISTER MOBILE
436 !***************************************************************
437 Register:!
438 !
439 PRINT "Pls. Power On MS, Then Press F2 Continue"
441 PAUSE
442 PRINT "Register MS on 8960"
443 OUTPUT Testset;"CALL:MS:REPORTED:CLEAR:ALL"
!Clear MS reported database
444 OUTPUT Testset;"CALL:REG"
445 Reg_timer=TIMEDATE
446 LOOP
448 OUTPUT Testset;"CALL:MS:REP:ESN:HEX?"
449 ENTER Testset;Esn$
450 Reg_time=TIMEDATE-Reg_timer
469 EXIT IF LEN(Esn$)>3 OR Reg_time>30
470 END LOOP
472 IF Reg_time>30 THEN
473 PRINT "Registration Timed Out, Check Phone Setup"
474 GOTO End_program
475 END IF
477 PRINT "Mobile Registration Complete"
478 PRINT
482 !
483 !***************************************************************
484 ! PRINT MOBILE REGISTRATION INFO
485 !***************************************************************
486 !
487 !Read registration information
488 !
489 OUTPUT Testset;"CALL:MS:REP:ESN:HEX?"
490 ENTER Testset;Esn$
491 OUTPUT Testset;"CALL:MS:REP:MCC?"
492 ENTER Testset;Mcc$
493 OUTPUT Testset;"CALL:MS:REP:MNC?"
494 ENTER Testset;Mnc$
495 OUTPUT Testset;"CALL:MS:REP:MSIN?"
496 ENTER Testset;Msin$
497 OUTPUT Testset;"CALL:MS:REP:BCLASS?"
498 ENTER Testset;Bclass$
499 OUTPUT Testset;"CALL:MS:REP:EIRP?"
500 ENTER Testset;Eirp$
501 OUTPUT Testset;"CALL:MS:REP:OPER:MODE?"
502 ENTER Testset;Opmode$
503 OUTPUT Testset;"CALL:MS:REP:PREV?"
504 ENTER Testset;Prev$
507 PRINT "Mobile Registration Information:"
508 PRINT
509 Print_res_str("Mobile ESN:",Esn$)
510 Print_res_str("Mobile MCC:",Mcc$)
511 Print_res_str("Mobile MNC:",Mnc$)
512 Print_res_str("Mobile MSIN:",Msin$)
513 Print_res_str("Mobile BAND CLASS:",Bclass$)
514 Print_res_str("Mobile EIRP:",Eirp$)
515 Print_res_str("Mobile OP MODE:",Opmode$)
516 Print_res_str("Mobile P_REV:",Prev$)
518 PRINT
519 !
520 RETURN
522 !
703 !**************************************************************
704 ! CONNECT CALL
705 !**************************************************************
706 Connect:!
707 !
708 !***Page the mobile station***
709 !
710 Connect_tries=0
711 PRINT "Paging mobile station..."
714 LOOP
715 !
716 OUTPUT Testset;"CALL:ORIG"!Pages the mobile station
717 OUTPUT Testset;"CALL:CONNECTED:STATE?"
!Queries for connected/idle state
718 ENTER Testset;Call_connected
719 Connect_tries=Connect_tries+1
720 IF NOT Call_connected THEN
721 WAIT .2
723 END IF
724 EXIT IF Call_connected OR Connect_tries=50
725 END LOOP
726 IF NOT Call_connected THEN
727 PRINT "Call attempt failed"
728 GOTO End_program
729 ELSE
730 PRINT "Call connected"
731 Current_chan=Primary_channel
732 END IF
733 PRINT
736 RETURN
737 !
747 !**************************************************************
748 ! Mutitone_up: Uplink Audio measurement mode is used to test
749 ! the analog signals by decoding the speech frames
750 ! received from the R-Traffic/R-FCH channel over the RF
751 ! link so that the connectivity and performance of the
752 ! analog signal handling compo
752 !**************************************************************
753 Multitone_up:!
754 !
755 DIM Mta_lev$[1000]
!Define an arry to hold multitone measurement results
758 OUTPUT Testset;"CALL:FCHannel:SOURce NFRames"
!Set up the Voice SO Mode required for the uplink measurement.
759 !*** multi-tone audio measurement setup ***
760 !1. Set up audio generator parameters for uplink test
762 OUTPUT Testset;"SETup:CMAudio:GENerator:FREQuency:
UPLink:PRESet NARRow"!Set up uplink frequency
763 OUTPUT Testset;"SETup:CMAudio:GENerator:LEVel:
UPLink:ALL:TOTal 1"!Set up uplink level to 1V
764 !2. Set up audio analyzer parameters for uplink test.
765 OUTPUT Testset;"SETup:CMAudio:ANALyzer:FREQuency:all:
GENerator ON"!Set up audio analyzer frequency to on
766 !3. Set up multitone measurement limit lower and upper level
767 OUTPUT Testset;"SETup:CMAudio:LEVel:ALL:LIMit:LOWer -25,-25,-25,
-50,-50,-50,-75,-75,-75,-100,-100,-100,-100,-100,-75,-75,-75,
-50,-50,-50"
768 OUTPUT Testset;"SETup:CMAudio:LEVel:ALL:LIMit:UPPer 25,25,25,
50,50,50,75,75,75,100,100,100,100,100,75,75,75,50,50,50"
769 !4. Set up multitone measurement
770 OUTPUT Testset;"SETup:CMAudio:COUNt 10"
!Set the Multi-Measurement Count to 10
771 OUTPUT Testset;"SETup:CMAudio:MEASurement:MODE UPLink"
!Set the Measurement Mode to Uplink Audio
772 OUTPUT Testset;"SETup:CMAudio:REFerence:MODE ABSolute"
!Set the Analyzer 0dB Reference Mode to Absolute
773 OUTPUT Testset;"SETup:CMAudio:REFerence:ABSolute:
LEVel:UPLink 50"
!Set the Analyzer Uplink Reference Level to 50%
774 OUTPUT Testset;"SETup:CMAudio:SETTling 600 ms"
!Set device settling time to 600 ms
775 OUTPUT Testset;"SETup:CMAudio:CONTinuous OFF"
!Set the Trigger Arm to Single
779 !Measure uplink multitone
780 PRINT "MultiTone Audio Uplink Test Result"
781 OUTPUT Testset;"INITiate:CMAudio"
785 OUTPUT Testset;"FETCh:CMAudio:INTegrity?"
790 ENTER Testset;Integrity
791 OUTPUT Testset;"FETCh:CMAudio:LEVel?"
800 ENTER Testset;Mta_lev$
805 OUTPUT Testset;"FETCh:CMAudio:LEVel:LIMit:FAIL?"
810 ENTER Testset;Result
811 Print_results("Integrity indicator = ",Integrity,"")
812 FOR I=1 TO 20
813 Comma=1+(I-1)*17
814 Print_results("Tone "&VAL$(I),
VAL(Mta_lev$[Comma;16]),"dB")
815 NEXT I
816 PRINT "Uplink Multitone Test Result vs.
Lower/Upper Limit(0=Pass, 1=Fail): ";Result
817 RETURN
818 !
2120 !*************************************************************
2121 ! End of All Testing Cleanup
2122 !*************************************************************
2123 End_program:!
2124 !
2128 OUTPUT Testset;"CALL:END"
2129 PRINT "End of Program"
2138 END
2139 !
2140 !*************************************************************
2141 ! Sub-program Section
2142 !*************************************************************
2143 !
2144 Timeout: SUB Timeout! Global timeout handler (from Step 1)
2145 COM Testset
2146 PRINT "Program timed out"
2147 CLEAR 7
2148 CLEAR Testset
2149 STOP
2150 SUBEND
2151 !
2152 Print_results: SUB Print_results(Meas_name$,Res1,Units$)
2153 !
2154 PRINT USING "5X,50A,5X,M8D.4D,1X,15A";
Meas_name$;Res1;Units$
2155 !
2156 SUBEND
2157 !
2158 Print_res_str: SUB Print_res_str(String_name$,Results$)
2159 !
2160 PRINT USING "5X,30A,5X,20A";String_name$;Results$
2161 !
2162 SUBEND
2164
|
|
top
of page