Programming a Signaling Tone Measurement

General Programming Procedure

1. Make a call.
2. Configure the Signaling Tone setup parameters using SETup:STONe subsystem.
3. Trigger the Signaling Tone using CALL:MS:ANALog:MAINtenance[:IMMediate] or CALL:MS:ANALog:ALERt[:IMMediate] .
4. Start the signaling tone measurement and obtain the measurement result using READ:STONe[:ALL]? subsystem.

Programming Example

 
1        ! This program measures the signaling tone
3        !
6        CLEAR SCREEN
7        ! E5515C GPIB Address
8        Testset=714
9        ! System type
11       Systype$="AMPS"
12       ! System identification
13       Sid=1
14       !
15       ! Calls "Timeout" routine
16       ON TIMEOUT 7,20 CALL Timeout
17       !
18       ! *** Specify call parameters ***
19       OUTPUT Testset;"SYST:COMM:GPIB:DEB:STAT ON"
20       ! Sets Operating Mode to be Active Cell
21       OUTPUT Testset;"CALL:OPER:MODE CALL"
22       ! Set System Type to be AMPS
23       OUTPUT Testset;"CALL:SYST ";Systype$
24       ! Set System Identification
25       OUTPUT Testset;"CALL:SID:AMPS";Sid
64       !
68       ! *** Make a call by paging the mobile station ***
69       PRINT "Turn on mobile station..."
70       PRINT "Press continue when it has found service and registred"
71       PAUSE
72       PRINT "Paging mobile station..."
73       PRINT "Answer the mobile station when you are ready"
74       ! Originate the call
75       OUTPUT Testset;"CALL:ORIG"
76       ! Query for connected/idle state
77       OUTPUT Testset;"CALL:CONN:STAT?"
78       ENTER Testset;Call_connected
79       IF NOT Call_connected THEN
80          DISP "Call attempt failed"
81          STOP
82       ELSE
83          DISP "Call connected"
84       END IF
85       PRINT "Connection is established, test is in progress"
86       !
87       ! *** Configure signaling tone measurement parameters ***
88       ! Set trigger arm state to be single
89       OUTPUT Testset;"SET:STON:CONT OFF"
90       ! Turn on multi measurement
91       OUTPUT Testset;"SET:STON:COUN:STAT ON"
92       ! Set the number of measurements to 30
93       OUTPUT Testset;"SET:STON:COUN:NUMB 30"
95       !
96       ! *** Start the signaling tone measurement ***   
98       ! Send the maintainence order message to mobile station
99       OUTPUT Testset;"CALL:MS:ANAL:MAIN"
100      !
101      ! *** Obtain the signaling tone measurement results ***   
103      ! Start the measurement and get the measurement results
104      OUTPUT Testset;"READ:STON:ALL?"
105      ENTER Testset;Integrity,Ppeak_dev,Npeak_dev,Freq_err,Freq
106      DISP "Signaling Tone Test complete"
109      ! Turn off the measurement
110      OUTPUT Testset;"INIT:STON:OFF"
111      ! End the call
112      OUTPUT Testset;"CALL:END"
113      !
114      ! *** Display the measurement results ***
115      PRINT "STONE =";Ppeak_dev;Npeak_dev;Freq_err;Freq;
116      PRINT "Integrity Indicator";Integrity
117      PRINT "Stone Positive Peak Deviation = ";Ppeak_dev
118      PRINT "Stone Negative Peak Deviation = ";Npeak_dev
119      PRINT "Stone Frequency Error = ";Freq_err
120      PRINT "Stone Frequency = ";Freq
121  END
122  !
132  ! Global timeout handler
185  Timeout: SUB Timeout
187             PRINT "Program timed out"
188             CLEAR 7
189             CLEAR 714
190           SUBEND

Returned Values

The measurements returned by this program are:

• Integrity returns the measurement integrity indicator (see Integrity Indicator ); 0 means a successful measurement with no errors.
• Ppeak_dev returns the average positive peak frequency deviation of carrier in kHz.
• Npeak_dev returns the average negative peak frequency deviation of carrier in kHz.
• Freq_err returns the average frequency error of carrier in Hz.
• Freq returns the average frequency of carrier in Hz.

Related Topics

Signaling Tone Measurement Description

Signaling Tone Troubleshooting

INITiate

SETup:STONe

FETCh:STONe