Programming a TDSO Frame Error Rate Measurement

Last updated: October 28, 2004

This section provides an example of how to make a TDSO (Test Data Service Option) FER measurement via the GPIB.

The following program example assumes that the mobile station's antenna output is connected to the RF IN/OUT connector, and the mobile station has found service.

The basic procedure to test TDSO FER is as follows:

Make a SO 32 (F-SCH) call (see CALL:SOPTion ).
Configure the TDSO FER Setup parameters using the SETup:TFERror subsystem.
Start the TDSO FER measurement using the INITiate subsystem.
Use the FETCh:TFERror command to obtain the measurement results.

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\tdso_fer.txt"
20    !This program measures tdso (test data service option) frame error rate
30    !See "Receiver Sensitivity and Dynamic Range" in TIA/EIA-98-D for specifications and
standards
40    CLEAR SCREEN
50    A=714
60    !***Specify call parameters***
70    Systype$="DIGITAL2000" !Cell System Type
80    Band$="USPC" !US PCS band
90    Channel=1125 !RF Channel
100   Sid=1 !System Identification
110   Nid=1 !Network Identification
120   Radio_config$="F3R3" !Radio Configuration
130   Service_opt$="SOFS32" !Service Option SO32 (+F-SCH). This service option must be
selected
140   !before bringing up a call for testing tdso fer
141   !
150   !***Specify test parameters***
160   Loss_frequency$="836 MHZ,881 MHZ" !Reverse channel, forward channel frequencies for
amplitude offset (path loss)
170   Expected_loss$="-2,-2" !Path loss at reverse channel, forward channel frequencies
180   Ior=-60 !Cell power
190   Pilot=-7 !Pilot channel power level
200   Traffic=-15.5 !Traffic channel power level
201   Confidence=2 !Confidence requirement ratio
210   !
220   ON TIMEOUT 7,30 CALL Timeout ! Calls "Timeout" routine
240   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON" !Turns debug state on
250   !
260   !***Set up path loss***
270   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$ !Enters frequencies in
Amplitude Offset table
280   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$ !Enters loss values in Amplitude
Offset table
290   !
300   !***Set up call parameters***
310   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
320   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
330   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell Band for selected System Type
340   OUTPUT A;"CALL:CHAN ";Channel ! Sets Channel for selected System Type and Cell Band
350   OUTPUT A;"CALL:POWER -50" !Sets and turns on Cell Power for selected System Type
360   OUTPUT A;"CALL:SID ";Sid! Sets System Identification
370   OUTPUT A;"CALL:NID ";Nid! Sets Network Identification
380   OUTPUT A;"CALL:RCON ";Radio_config$ !Sets Radio Configuration
390   OUTPUT A;"CALL:SOPTION ";Service_opt$ !Sets service option for selected System Type and
Radio Configuration
400   OUTPUT A;"CALL:PROT PREV6" !Sets Protocol Revision for the selected System Type
410   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets Paging channel data rate to full rate
420   OUTPUT A;"CALL:PIL -7"    !Sets Pilot to default
430   OUTPUT A;"CALL:SYNC -16"  !Sets Sync to default
440   OUTPUT A;"CALL:PAG -12"   !Sets Paging to default
450   OUTPUT A;"CALL:FCH -15.6" !Sets Traffic to default
460   !
470   PRINT "Turn on mobile station...press continue when it has found service and registered"
480   PAUSE
490   CLEAR SCREEN
500   OUTPUT A;"CALL:REG:TIMER:STATE 0" !Turns timer-based registrations off
510   WAIT 2 !Waits 2 seconds for any timer-based registrations to clear out
520   !
530   !***Page the mobile station***
540   DISP "Paging mobile station..."
550   OUTPUT A;"CALL:ORIG" !Pages the mobile station
560   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state...hangs until state
change detector is disarmed
570   ENTER A;Call_connected
580   IF NOT Call_connected THEN
590     DISP "Call attempt failed"
600     STOP
610   ELSE
620     DISP "Call connected"
630   END IF
640   !
650   !***Set up measurement parameters***
660   OUTPUT A;"SETUP:TFERROR:CONTINUOUS OFF" !Sets trigger arm state to single
670   OUTPUT A;"CALL:POW ";Ior ! Sets Cell Power for the selected System Type
680   OUTPUT A;"CALL:PIL ";Pilot !Sets Pilot channel level
690   OUTPUT A;"CALL:FCH ";Traffic !Sets Traffic channel level
691   OUTPUT A;"SETUP:TFERROR:CONFIDENCE:REQUIREMENT:RATIO ";Confidence
700   !
710   !***Obtain measurement results***
720   OUTPUT A;"INITIATE:TFERROR" !Initiates a frame error rate measurement
730   DISP "Measuring TDSO FER"
731   LOOP
732   WAIT 1
740   OUTPUT A;"INIT:DONE?"
760   ENTER A;Tfer_done$
770   EXIT IF Tfer_done$="TFER"
780   END LOOP
800   OUTPUT A;"FETCh:TFERROR?" !Queries the test set for frame error rate measurement results
805   DISP "FER test completed"
810   ENTER A;Integrity,Fer,Rx_good,Rx_blank,Tx_good,Tx_blank,Conf
820   !
940   PRINT "Integrity indicator = ";Integrity
950   PRINT "TDSO FER test results = ";Fer
960   PRINT "Number of received good frames = ";Rx_good
961   PRINT "Number of received blank frames = ";Rx_blank
962   PRINT "Number of transmitted good frames = ";Tx_good
963   PRINT "Number of transmitted blank frames = ";Tx_blank
964   PRINT "Confidence result = ";Conf
970   DISP "Test complete"
980   !***Return to default call processing states***
990   OUTPUT A;"CALL:POW:DIG2000 -50" ! Returns cell power to -50 dBm/1.23 MHz
1000  OUTPUT A;"CALL:REG:TIMER:STATE ON" !Returns timer-based registration to ON
1010  !
1020  OUTPUT A;"CALL:END" !Ends the call
1030  END
1040 Timeout: SUB Timeout    ! Global timeout handler
1050    PRINT "Program timed out"
1060    CLEAR 7
1070    CLEAR 714
1080  SUBEND

Programming a TDSO Frame Error Rate Measurement

Programming Example

Related Topics