Programming a TROLP Measurement

Programming Example

 
10    RE-SAVE "c:\roadhog\programs\trolp.txt"
20    !This program measures time response to open loop power control
30    !See "Time Response of Open Loop Power Control" in TIA/EIA-98-D for specifications 
40    CLEAR SCREEN
50    A=714
60    !***Specify call parameters***
70    Systype$="DIGITAL2000" !Cell System Type
80    Band$="USC" !Frequency Band
90    Channel=384 !RF Channel
100   Sid=1 !System Identification
110   Nid=1 !Network Identification
120   Radio_config$="F3R3" !This example will test radio configuration 3 only
130   Service_opt$="SO2" !Service Option
150   !
160   !***Specify test parameters***
170   Loss_frequency$="1900 MHZ,1945 MHZ" !frequencies for amplitude offset (path loss)
180   Expected_loss$="-10,-10" !Path loss at reverse channel, forward channel frequencies
190   Ior=-60 !Starting cell power for TROLP testing
200   Pilot=-7 !Pilot channel power level for TROLP testing
210   Traffic=-7.4 !Traffic channel power level for TROLP testing
220   !
230   !
240   ON TIMEOUT 7,20 CALL Timeout ! Calls "Timeout" routine
250   OUTPUT A;"SETUP:TROP:TIMEOUT:STIME 10 S" !Sets TROLP measurement timeout to 10 seconds
260   OUTPUT A;"SYST:COMM:GPIB:DEB:STAT ON" !Turns debug state on
270   !
280   !***Set up path loss***
290   OUTPUT A;"SYSTEM:CORRECTION:SFREQUENCY ";Loss_frequency$ ! Amplitude Offset table
300   OUTPUT A;"SYSTEM:CORRECTION:SGAIN ";Expected_loss$ ! Amplitude Offset table
310   !
320   !***Set up call parameters***
330   OUTPUT A;"CALL:OPER:MODE CALL" !Sets Operating Mode to Active Cell
340   OUTPUT A;"CALL:SYSTEM ";Systype$ !Sets System Type
350   OUTPUT A;"CALL:BAND ";Band$ !Sets Cell Band for selected System Type
360   OUTPUT A;"CALL:CHAN ";Channel ! Sets Channel for selected System Type and Cell Band
370   OUTPUT A;"CALL:POWER -50" !Sets and turns on Cell Power for call setup
380   OUTPUT A;"CALL:SID ";Sid! Sets System Identification
390   OUTPUT A;"CALL:NID ";Nid! Sets Network Identification
400   OUTPUT A;"CALL:RCON ";Radio_config$ !Sets Radio Configuration
410   OUTPUT A;"CALL:SOPTION ";Service_opt$ !service option for System Type and 	Radio Config
420   OUTPUT A;"CALL:PROT PREV6" !Sets Protocol Revision for the selected System Type
430   OUTPUT A;"CALL:PAG:DRAT FULL" !Sets Paging channel data rate to full rate
450   OUTPUT A;"CALL:PIL -7"    !Sets Pilot to default
460   OUTPUT A;"CALL:SYNC -16"  !Sets Sync to default
470   OUTPUT A;"CALL:PAG -12"   !Sets Paging to default
480   OUTPUT A;"CALL:FCH -15.6" !Sets Traffic to default
490   !
500   PRINT "Turn on mobile station...press continue when it has found service and registered"
510   PAUSE
520   CLEAR SCREEN
530   OUTPUT A;"CALL:REG:TIMER:STATE OFF" !Turns timer-based registrations off
540   WAIT 2 !Waits 2 seconds for any timer-based registrations to clear out
550   !
560   !***Page the mobile station***
570   DISP "Paging mobile station..."
580   OUTPUT A;"CALL:ORIG" !Pages the mobile station
590   OUTPUT A;"CALL:CONNECTED:STATE?" !Queries for connected/idle state
600   ENTER A;Call_connected
610   IF NOT Call_connected THEN
620     DISP "Call attempt failed"
630     STOP
640   ELSE
650     DISP "Call connected"
660   END IF
670   !
680   !***Set up measurement parameters***
681   OUTPUT A;"CALL:POW ";Ior ! Sets Cell Power for TROLP measurement
682   OUTPUT A;"CALL:PIL ";Pilot !Sets Pilot channel level
683   OUTPUT A;"CALL:FCH ";Traffic !Sets Traffic channel level
684   !
685   GOSUB Start_meas_down !Steps Ior down 20 dB
686   GOSUB Start_meas_up !Steps Ior up 20 dB
687   GOSUB Start_meas_up !Steps Ior up 20 dB
688   GOSUB Start_meas_down !Steps Ior down 20 dB
689   GOTO End_program
691 Start_meas_down:  ! Subroutine to measure -20 dB step in cell power
692   !***Obtain pass/fail measurement results for 20 dB step down in cell power***
693   OUTPUT A;"SETUP:TROP:STEP DOWN20"
694   OUTPUT A;"INITIATE:TROP" !Initiates a time response of open loop power control
695   DISP "Measuring mobile station response to open loop power control"
696   OUTPUT A;"FETCh:TROP?" !Queries the test set for TROLP measurement results
697   DISP "Time response of open loop power control measurement completed"
698   ENTER A;Integrity,Passfail
699   SELECT Passfail !Assign pass/fail results to a string
700   CASE 0
701     Pass_fail$="PASSED"
702   CASE 1
703     Pass_fail$="FAILED"
704   END SELECT
705   PRINT "Integrity indicator = ";Integrity
706   PRINT "+20 dB step results = ";Pass_fail$
707   RETURN
709   !
710 Start_meas_up:  ! Subroutine to measure +20 dB step in cell power
890   !***Obtain pass/fail measurement results for 20 dB step up in cell power***
891   OUTPUT A;"SETUP:TROP:STEP UP20"
892   OUTPUT A;"INITIATE:TROP" !Initiates a time response of open loop power control
893   DISP "Measuring mobile station response to open loop power control"
894   OUTPUT A;"FETCh:TROP?" !Queries the test set for TROLP measurement results
895   DISP "Time response to open loop power control measurement completed"
896   ENTER A;Integrity,Passfail
897   SELECT Passfail !Assign pass/fail results to a string
898   CASE 0
899     Pass_fail$="PASSED"
900   CASE 1
901     Pass_fail$="FAILED"
902   END SELECT
903   PRINT "Integrity indicator = ";Integrity
904   PRINT "-20 dB step results = ";Pass_fail$
905   RETURN
907   !
917 End_program:  !
990   OUTPUT A;"CALL:END" !Ends the call
1000  END
1010 Timeout: SUB Timeout    ! Global timeout handler
1020    PRINT "Program timed out"
1030    CLEAR 7
1040    CLEAR 714
1050  SUBEND

Related Topics

Time Response of Open Loop Power Control (TROLPC) Measurement Description

Measuring Time Response of Open Loop Power Control (TROLPC)

Time Response of Open Loop Power Control (TROLPC) Troubleshooting

Control Program Example

SETup:TROPower

INITiate

FETCh:TROPower

READ

ABORt