Block Error Rate (
BLER) Reports Description
Last updated: May 8, 2002
These reports are
not
applicable to GSM.
Block Error Rate (BLER) reports can be used in the production process to test the performance of a GPRS mobile station's receiver. The BLER result is derived from the Radio Link Control (RLC) layer's Packet ACK/NACK (Acknowledged/Not Acknowledged) message. BLER is simply the ratio of the number of negatively acknowledged blocks to the total number of blocks acknowledged by the mobile station.
The test set uses an Agilent proprietary data connection to enable BLER reports to be retrieved from the mobile station (For details on how to set the data connection type to BLER, see
CALL:FUNCtion:DATA:TYPE
).
The BLER reports which the test set provides are based on GPRS receiver tests defined in 3GPP 51.010 (formerly ETSI GSM 11.10), section 14.16.
As well as BLER reports, the test set also provides a Block Error measurement (see
Block Error Measurement Description
). Starting or aborting a Block Error measurement does not affect the BLER reports. In addition, resetting the BLER reports does not affect the BLER measurement.
When are BLER Reports Made?
You obtain BLER results using the GPIB query
CALL:STATus:PDTCH | PDTChannel:BLERror?
. This query returns the percentage of blocks tested that were in error and the total number of blocks used to generate the BLER result. To reset the BLER result you must use
SYSTem:MEASurement:RESet
. The BLER result does not reset automatically when you connect a different GPRS mobile station.
The BLER results are only available when the data connection status is transferring (TRAN). If you require details on data connection states, see
Data Connection Processing State Synchronization
.
Using Different Power Levels on Downlink Timeslots
The BLER results are calculated across all active downlink timeslots, not on any individual downlink timeslot.
When using the multislot configurations which provide two downlinks (D2U1 and D2U2), the test set requests Packet ACK/NACK (Acknowledged/Not Acknowledged) messages from the mobile station on timeslot 4. ETSI specifies that the mobile station must respond to these requests on the same timeslot. If the downlink on timeslot 4 degrades severely (and thus has a large number of block errors), the mobile station may be unaware of a request for Packet ACK/NACK messages. If this happens, the BLER reports may hang for long periods or stop completely. This may cause the data connection to stop after a few seconds.
Programming BLER Reports
This section provides an example of how to use BLER reports to test your mobile station's receiver via GPIB.
The following procedure assumes that a data connection has been established between the test set and the mobile station (connection status is Transferring). See
Step 4: Make a connection
.
-
Configure the BCH and PDTCH parameters using the CALL subsystem.
-
Reset the BLER results using the SYSTem:MEASurement:RESet command.
-
Use the CALL:STATus:PDTCH:BLERror? query to obtain the first BLER results.
-
Re-configure the downlink PDTCH power level of one of the bursts using the CALL subsystem.
-
Reset the BLER results again using the SYSTem:MEASurement:RESet command.
-
Use the CALL:STATus:PDTCH:BLERror? query to obtain the second BLER results.
Programming Example
10 ! This code assumes that the current data connection state is Transferring.
20 !
30 ! Configure BCH and PDTCH parameters
40 OUTPUT 714;"CALL:PDTCH:BAND PGSM" ! Set the PDTCH band.
50 OUTPUT 714;"CALL:POW -60" ! Set the BCH level to -60 dBm
60 OUTPUT 714;"CALL:PDTCH:MSL:CONF D2U1" ! Set the multislot configuration to
70 ! two downlinks, one uplink.
80 OUTPUT 714;"CALL:PDTCH:PZER:LEV 30" ! Set the P0 reference level to 30 dB.
90 OUTPUT 714;"CALL:PDTCH:CSCH CS4" ! Set the channel coding scheme to CS4.
100 !
110 ! Perform a measurement reset to ensure a stable data connection.
120 OUTPUT 714;"SYST:MEAS:RES"
130 ! Read initial BLER ensuring that result is over 2000 blocks at least
140 REPEAT
150 OUTPUT 714;"CALL:STAT:PDTCH:BLER?"
160 ENTER 714;Bler_initial,Blocks_initial
170 UNTIL (Blocks_initial>=2000 AND Blocks_initial<=2300) ! <= required for
180 ! NAN (9.91E+37) case.
190 !
200 ! Print results at initial downlink PDTCH power level
210 ! of -90 dBm(-60 dBm BCH level - 30 dB P0 level)
220 PRINT "Blocks tested at -90 dBm = ";Blocks_initial
230 PRINT "BLER Result at downlink PDTCH power of -90 dBm = ";Bler_initial
240 !
250 ! Set up and select the downlink PDTCH power reduction levels.
260 OUTPUT 714;"CALL:PDTCH:PRED:LEV1 11db"
270 OUTPUT 714;"CALL:PDTCH:PRED:LEV2 0dB"
280 OUTPUT 714;"CALL:PDTCH:PRED:BURS1 PRL1"
290 OUTPUT 714;"CALL:PDTCH:PRED:BURS2 PRL2"
300 OUTPUT 714;"SYST:MEAS:RES" ! Reset the BLER results
310 !
320 ! Now obtain the second set of BLER results when burst 1 has a lower
330 ! power level which introduces more block errors.
340 REPEAT
350 OUTPUT 714;"CALL:STAT:PDTCH:BLER?"
360 ENTER 714;Bler_second,Blocks_second
370 UNTIL (Blocks_second>=2000 AND Blocks_second<=2300)
380 !
390 ! Print results when downlink burst 1 is at lower downlink PDTCH
400 ! power level of -101 dBm(-60 dBm BCH level - 30 dB P0 level - 11 dB power
410 ! reduction level).
420 PRINT
430 PRINT "Blocks tested at -101 dBm = ";Blocks_second
440 PRINT "BLER Result at downlink PDTCH power of -101 dBm = ";Bler_second
450 END
Returned Values
The BLER reports returned by this program are:
-
Blocks_initial
returns the number of blocks tested to calculate the first BLER result.
-
Bler_initial
returns the BLER result, in percent (%) when the downlink PDTCH power levels of both bursts are at -90 dBm.
-
Blocks_second
returns the number of blocks tested to calculate the second BLER result.
-
Bler_second
returns the second BLER result, in percent (%). This result has been obtained when the downlink PDTCH power level of the first burst has been reduced by 11 dB to -101 dBm.
