Programming in Fast Device Tune Operating Mode

Programming Example

 
80        ! ====================================================================
90        ! This program is intended to calibrate the receiver of a mobile
100       ! ====================================================================
110       !
120       ! *** Initialize Program Variables ***
130       !
140         OPTION BASE 0
150         Testset=714
160         CLEAR SCREEN
170         CLEAR 7
180         CLEAR Testset
190         PRINT "*** Fast Device Tune transmitter calibration Program ***"
200         PRINT
210         !
220         !***Set up GPIB timeout***
230         ON TIMEOUT 7,32 CALL Timeout
240         ! Call "Timeout" routine after 32 seconds of GP-IB hang-up
250         !
260         !*** Variable declarations for the FDT measurements ***
270         !
280         Op_mode$="FDT"   !Operation mode.
290         Num_dts_steps=5  !Number of Downlink Sequence Steps
300         !
310         !Uncomment the pass loss varables and set the value as needed.
320         !Loss_frequency$=" 8.3652E+8,8.60E+8" !Set frequencies for path loss.
330         !Expected_loss$=" -1.5,-1.5" !Set path loss at frequencies specified
340         !
350         !************************************
360         !***Simple Test Executive
370         !************************************
380         !
390         GOSUB Preset_test_set
400             !End any current connection and preset test set
410         !GOSUB Set_path_loss
420             !If needed, uncomment this line and set the pass loss required for your test.
430         GOSUB Set_init_cond
440             !Set initial conditions required for the FDT test
450         GOSUB Set_dts_series
460             !Set up and transmit the DTS
470         GOTO End_program
480             !End the program
490         !
500         !**************************************************************************
510         ! BEGINNING OF SUBROUTINES
520         !**************************************************************************
530         !
540  Preset_test_set:             !
550         !*******************************************************************
560         ! Subroutine: Preset the test set
570         !*******************************************************************
580         !
590         OUTPUT Testset;"*Rst"
600             ! Full preset test set
610         OUTPUT Testset;"*OPC?"
620         ENTER Testset;Opc$
630         RETURN
640         !
650  Set_path_loss:         !
660         !*******************************************************************
670         ! Subroutine: Set path loss values
680         !*******************************************************************
690         !
700         OUTPUT Testset;"SYST:CORR:FREQ";Loss_frequency$
710             ! Set the frequencies for amplitude offset
720         OUTPUT Testset;"SYST:CORR";Expected_loss$
730             ! Set the amplitude offsets for above frequencies
740         RETURN
750         !
760  Set_init_cond:         !
770         !*******************************************************************
780         ! Subroutine: Set initial conditions required for the FDT Test
790         !*******************************************************************
800         !
810         OUTPUT Testset;"CALL:OPER:MODE ";Op_mode$
820             !Set Operating Mode to Fast Device Tune Mode
830         RETURN
840         !
850  Set_dts_series:           !
860         !*******************************************************************
870         ! Subroutine: Set up the downlink test sequence for MS Receiver test
880         !*******************************************************************
890         !
900         !
910         PRINT "*** Set DTS Continuous to OFF***"
920         OUTPUT Testset;"GFDT:DOWN:TSEQ:CONT 0"
930         PRINT
940         PRINT "*** Set the number of DSSs in the DTS to 5***"
950         OUTPUT Testset;"GFDT:DOWN:TSEQ:SST ";Num_dts_steps
960         PRINT "Number of DSS in the DTS =";Num_dts_steps
970         PRINT
980         PRINT "*** Set DTS power level Allocation ***"
990         OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:FRAM PL1,MIX"
1000        PRINT
1010        PRINT "*** Set DTS power level ***"
1020        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV1 -50"
1030        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV2 -60"
1040        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV3 -70"
1050        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV4 -80"
1060        PRINT
1070        PRINT "*** Set DTS Power Levels for TS1 through TS5 ***"
1080        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL0 PL1"
1090        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL1 PL2"
1100        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL2 PL3"
1110        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL3 PL4"
1120        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL4 PL3"
1130        OUTPUT Testset;"GFDT:DOWN:TSEQ:PLEV:TSL5 PL2"
1140        PRINT
1150        PRINT "*** Set DTS frequency for each DSS ***"
1160        OUTPUT Testset;"GFDT:DOWN:TSEQ:FREQ 9e+8,8.5e+8,9e+8,9.5e+8,1e+9"
1170        PRINT
1180        PRINT "*** Set DTS Repeat Count for each step ***"
1190        OUTPUT Testset;"GFDT:DOWN:TSEQ:REP 10,1,1,1,2"
1200        PRINT
1210        PRINT "*** Set DTS Burst Type for TS1 through TS5 ***"
1220        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL0 FCB,FSB,FSB,DUMMY,PRBS"
1230        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL1 DUMMY,PRBS,FSB,DUMMY,PRBS"
1240        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL2 DUMMY,PRBS,DUMMY,DUMMY,PRBS"
1250        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL3 DUMMY,PRBS,DUMMY,DUMMY,PRBS"
1260        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL4 DUMMY,OFF,OFF,OFF,PRBS"
1270        OUTPUT Testset;"GFDT:DOWN:TSEQ:BURS:TYPE:TSL5 DUMMY,OFF,OFF,OFF,PRBS"
1280        PRINT
1290        !
1380        PRINT "Start the transmission of DTS"
1390        OUTPUT Testset;"GFDT:DOWN:TSEQ:STAR"
1400        PRINT
1410        !
1420        RETURN
1430         !
1440  End_program:          !
1450        !*******************************************************************
1460        ! Subroutine: End of all testing clean up
1470        !*******************************************************************
1480        !
1490        OUTPUT Testset;"*Rst"
1500            ! Full preset test set
1510        OUTPUT Testset;"*OPC?"
1520        ENTER Testset;Opc$
1530        PRINT
1540        PRINT "End of Program"
1550        END
1560        !
1570        !**************************************************************************
1580        ! SUB-PROGRAM SECTION: Global timeout handler
1590        !**************************************************************************
1610  Timeout: SUB Timeout
1620             PRINT
1630             PRINT "Program timed out, check setup"
1640             CLEAR 7
1650             CLEAR Testset
1660             STOP
1670        SUBEND
1680         !

Programming Example

 
10       ! ====================================================================
20       ! This program is intended to calibrate the transmitter of a mobile.
30       ! ====================================================================
40       !
50       ! *** Initialize Program Variables ***
60       !
70           OPTION BASE 0
80           Testset=714
90           CLEAR SCREEN
100          CLEAR 7
110          CLEAR Testset
120          PRINT "*** Fast Device Tune (GFDT) Measurement Program for GSM/GPRS/EGPRS***"
130          PRINT
140          !
150          !***Set up GPIB timeout***
160          ON TIMEOUT 7,32 CALL Timeout
170          ! Call "Timeout" routine after 32 seconds of GP-IB hang-up
180          !
190          ! *** Variable declarations for the FDT measurements ***
200          !
210          DIM Meas_bpow$[500],Meas_cpow$[500]
220          ALLOCATE REAL Meas_bpow_res(0:49),Meas_cpow_res(0:49)
230          !
240          Burst_measured=5 !Set the burst to be measured to 5
250          Op_mode$="FDT"   !Operation mode.
260          Meas_timeout=50  !Measurement timeout.
270          Num_uts_steps=5  !Number of Uplink Sequence Steps
280          Uts_burst_cnts=7 !Number of bursts per Uplink Sequence Steps
290          Arm_state=0      !The arm state of the transmit power measurement.
300          !
310          !Uncomment the pass loss varables and set the value as needed.
320          !Loss_frequency$=" 8.3652E+8,8.60E+8" !Set frequencies for path loss.
330          !Expected_loss$=" -1.5,-1.5" !Set path loss at frequencies specified
340          !
350          !************************************
360          !***Simple Test Executive
370          !************************************
380          !
390          GOSUB Preset_test_set
400          !End any current connection and preset test set
410          !GOSUB Set_path_loss
420          !If needed, uncomment this line and set the pass loss required for your test.
430          GOSUB Set_init_cond
440          !Set initial conditions required for the FDT test
450          GOSUB Check_ms_config
460          !Check MS configuration state
470          GOSUB Set_uts_series
480          !Set up the MS Tx Freq/Power Series
490          GOSUB Fetch_txp_res
500          !Query TXP measurement results
510          GOTO End_program
520          !
530          !
540          !**************************************************************************
550          ! BEGINNING OF SUBROUTINES
560          !**************************************************************************
570          !
580          !
590   Preset_test_set:             !
600          !*******************************************************************
610          ! Subroutine: Preset the test set
620          !*******************************************************************
630          !
640          OUTPUT Testset;"*Rst"
650              ! Full preset test set
660          OUTPUT Testset;"*OPC?"
670          ENTER Testset;Opc$
680          RETURN
690          !
700   Set_path_loss:         !
710          !*******************************************************************
720          ! Subroutine: Set path loss values
730          !*******************************************************************
740          !
750          OUTPUT Testset;"SYST:CORR:FREQ ";Loss_frequency$
760              ! Set the frequencies for amplitude offset
770          OUTPUT Testset;"SYST:CORR ";Expected_loss$
780              ! Set the amplitude offsets for above frequencies
790          RETURN
800          !
810   Set_init_cond:         !
820          !*******************************************************************
830          ! Subroutine: Set initial conditions required for the FDT Test
840          !*******************************************************************
850          !
860          OUTPUT Testset;"CALL:OPER:MODE ";Op_mode$
870              !Set Operating Mode to Fast Device Tune Mode
880          RETURN
890          !
900   Set_uts_series:            !
910          !*******************************************************************
920          ! Subroutine: Set up the uplink test sequence for MS transmitter test
930          !*******************************************************************
940          !
950          PRINT "*** Set the number of uplink sequence steps in the UTS to 5***"
960          OUTPUT Testset;"GFDT:UPL:TSEQ:SST ";Num_uts_steps
970          PRINT "Number of USS in the UTS =";Num_uts_steps
980          PRINT
990          PRINT "*** Set UTS Burst Count to 7 ***"
1000         OUTPUT Testset;"GFDT:UPL:TSEQ:BURS:COUN ";Uts_burst_cnts
1010         PRINT
1020         PRINT "*** Set UTS frequency for each USS ***"
1030         OUTPUT Testset;"GFDT:UPL:TSEQ:FREQ 9e+8,8.5e+8,9e+8,9.5e+8,1e+9"
1040         PRINT
1050         !
1060         PRINT "*** Set the TXP measurement related parameters***"
1070         OUTPUT Testset;"CALL:MOD:MAN:BURS1 GMSK"
1080         OUTPUT Testset;"CALL:MOD:MAN:BURS2 GMSK"
1090         OUTPUT Testset;"CALL:MOD:MAN:BURS3 GMSK"
1100         OUTPUT Testset;"CALL:MOD:MAN:BURS4 GMSK"
1110         OUTPUT Testset;"CALL:MOD:MAN:BURS5 GMSK"
1120         OUTPUT Testset;"CALL:MOD:MAN:BURS6 GMSK"
1130         OUTPUT Testset;"CALL:MOD:MAN:BURS7 GMSK"
1140             !Set the expected modulation format for each uplink burst.
1150         OUTPUT Testset;"RFAN:CONT:POW:AUTO OFF"
1160             !Set receiver power control to manual mode.
1170         OUTPUT Testset;"RFAN:MAN:POW:BURS1 13"
1180         OUTPUT Testset;"RFAN:MAN:POW:BURS2 13"
1190         OUTPUT Testset;"RFAN:MAN:POW:BURS3 13"
1200         OUTPUT Testset;"RFAN:MAN:POW:BURS4 13"
1210         OUTPUT Testset;"RFAN:MAN:POW:BURS5 13"
1220         OUTPUT Testset;"RFAN:MAN:POW:BURS6 13"
1230         OUTPUT Testset;"RFAN:MAN:POW:BURS7 13"
1240             !Set the power level that the test set's receiver is expecting
1250             !the mobile station uplink burst to transmit at to 13dBm.
1260         !
1270         OUTPUT Testset;"SET:TXP:TIM:STIME "&VAL$(Meas_timeout)
1280             !Set measurement timeout.
1290         !
1300         OUTPUT Testset;"SET:TXP:COUN:STAT OFF"
1310             !Set TXP multi measurement state.
1320         !
1330         OUTPUT Testset;"SET:TXP:TRIG:DEL 0"
1340             !Set TXP measurement trigger delay to zero.
1350             !
1390         OUTPUT Testset;"SET:TXP:RANG:AUTO OFF"
1400             !Set auto range to highest burst state to OFF.
1410             !
1450         OUTPUT Testset;"SET:TXP:SST:FRAMES?"
1460             !Query how many frames are required for each uplink sequence step
1470         !
1480         RETURN
1490         !
1500  Check_ms_config:               !
1510         !*******************************************************************
1520         ! Subroutine: Check MS Configuration Matching Test Set's
1530         !*******************************************************************
1540         PRINT "************** NOTE *****************************************"
1550         PRINT "Make sure that your MS is placed into a test mode, and is properly"
1560         PRINT "configured to transmit the UTS to the right number USSs and TDMA frames"
1570         PRINT "in each USS."
1580         PRINT "*************************************************************"
1590         PRINT
1600         LINPUT "Press ENTER when finished",Keyboard$
1610         RETURN
1620         !
1630  Fetch_txp_res:                    !
1640         !*******************************************************************
1650         ! Subroutine: Perform FDT Measurement
1660         !*******************************************************************
1670         !
1680         !
1690         PRINT "*** Initiate the transmit power measurement"
1710         OUTPUT Testset;"INIT:TXP"
1740         !
1750         PRINT "*** Check the Arm State of the transmit power measurement"
1760         LOOP
1761             OUTPUT Testset;"INIT:TXP:GFDT:ARM?";Arm_state
1762             EXIT IF Arm_state=1
1763             PRINT "The Transmit Power measurement is not armed"
1764         END LOOP
1770         !
1780         BEEP
1790         PRINT "Command the MS to start sending Uplink Test Sequence ..."
1800         LINPUT "Press ENTER when finished",Keyboard$
1810         !
1811         !
1820         !*********Fetch and display the measurement result for Burst 5*********
1821         OUTPUT Testset;"FETC:TXP:TSEQ:BPOW? ";Burst_measured
1830         ENTER Testset;Meas_bpow$
1840         OUTPUT Testset;"FETC:TXP:TSEQ:CPOW? ";Burst_measured
1850         ENTER Testset;Meas_cpow$
1860         !
1870         FOR N=0 TO Num_uts_steps-1
1880             Dynamic_mkr=(N*17)
1890             !Set up a marker that will jump to each comma in the ascii string
1900             Meas_bpow_res(N)=VAL(Meas_bpow$[Dynamic_mkr+1,Dynamic_mkr+16])
1910             Meas_cpow_res(N)=VAL(Meas_cpow$[Dynamic_mkr+1,Dynamic_mkr+16])
1920             !Convert ascii to a numeric value
1930         NEXT N
1940         !
1950         OUTPUT Testset;"FETC:TXP:INT?"
1960         ENTER Testset;Integrity
1970         !
1980         PRINT "*** Print MS Tx Measurement Results ***"
1990         PRINT
2000         PRINT "integrity=";Integrity
2010         PRINT "Number of UTS Steps = ";Num_uts_steps
2020         PRINT "Total Number of Meas Results = ";Num_uts_steps
2030         PRINT
2040         !
2050         PRINT "Burst Number #   Sequence Step #   Burst Power #   Carrier Power"
2060         PRINT
2070             FOR N=0 TO Num_uts_steps-1
2080                 PRINT Burst_measured," ",N+1," ",Meas_bpow_res(N)," ",Meas_cpow_res(N)
2090             NEXT N
2100         RETURN
2110         !
2120  End_program:          !
2130         !*******************************************************************
2140         ! Subroutine: End of all testing clean up
2150         !*******************************************************************
2160         !
2170         OUTPUT Testset;"*Rst"
2180             ! Full preset test set
2190         OUTPUT Testset;"*OPC?"
2200         ENTER Testset;Opc$
2210         PRINT
2220         PRINT "End of Program"
2230         DEALLOCATE Meas_bpow_res(*),Meas_cpow_res(*)
2240         END
2250         !
2260         !**************************************************************************
2270         ! SUB-PROGRAM SECTION
2280         !**************************************************************************
2290                 !
2300  Timeout: SUB Timeout                 ! Global timeout handler
2310              PRINT
2320              PRINT "Program timed out, check setup"
2330              CLEAR 7
2340              CLEAR Testset
2350              STOP
2360         SUBEND
2370         !

Returned Values

The measurements returned by this program are:

• Integrity returns the measurement integrity indicator (see Integrity Indicator ). 0 means a successful measurement with no errors.
• Burst Power returns the average carrier power in dBm of Burst 5 for all USSs.
• Carrier Power returns the average carrier power in dBm of Burst for all USSs5.

The MUI screen of the transmit power measurement displays the measurement results for the USS specified by the parameter Fast Device Tune Result Set only.