Discrete Phase and Amplitude vs. Time Measurement Program Example
The following example program does not apply for a continuous input waveform. This program demonstrates use of the Phase & Amplitude versus Time Measurement for a discrete waveform, but does not calibrate the Spectrum Monitor as recommended in step 1 in the procedure above. See
Programming the Spectrum Monitor Calibration
for an example of how to program the test set to calibrate the Spectrum Monitor.
Note: A 250 ms wait is needed after the measurement is initiated and before the measurement starts. Values for measurement interval center times and measurement interval widths are data values loaded into the Test Set. These data values are in the
Time_specs
subroutine at the end of this program.
10 Test_set=714
20 !Sets program variable "Test_set" equal to the Test Set's default GPIB address
30 !
40 ON TIMEOUT 7,15 CALL Timeout
50 !Timeout protection subroutine; after 15 seconds of inactivity,
60 ! the program stops and clears the GPIB bus (so the GPIB bus
70 ! doesn't hang)
80 !
90 !****Test Set Setup****!
100 !----------------------!
110 OUTPUT Test_set;"*RST"
120 !Resets all Test Set values to their default settings.
130 OUTPUT Test_set;"SYST:SYNC?"
140 ENTER Test_set;Sync_result
150 ! Ensures previous commands are complete before executing following
160 ! commands
170 !
180 !OUTPUT Test_set;"SYST:LOG:UI:GPIB:STAT ON"
190 !Turns on UI logging for GPIB troubleshooting; use web browser to
200 ! retrieve log; remove the command line after your program works
210 ! correctly
220 !
230 OUTPUT Test_set;"CALL:CELL:OPERating:MODE CW"
240 !Sets the operating mode to continuous wave.
250 !
260 OUTPUT Test_set;"RFAnalyzer:MANual:MEASurement:MFRequency 890.2 MHz"
270 !Sets the expected input frequency.
280 !
290 OUTPUT Test_set;"RFAnalyzer:CW:EXPected:POWer 10 dbm"
300 !Adjusts the Test Set to the expected power level (the maximum input level
310 ! in the TX waveform).
320 !
330 OUTPUT Test_set;"CALL:POWer:STATe OFF"
340 !Turns off the RF generator cell power, to remove any interference which
350 ! may affect the phone
360 !
370 !**** Setup for PAvT Measurement ****!
380 !------------------------------------!
390 OUTPUT Test_set;"SETup:PCALibration:TIMeout:STIMe 10"
400 !Sets the measurement timeout period to 10 seconds, and the state to on.
410 !
420 OUTPUT Test_set;"SETup:PCAL:TRIGger:SOURce RISE"
430 !Sets the trigger source as desired (RISE, IMMediate, or EXTernal).
440 !
450 OUTPUT Test_set;"SETup:PCAL:TRIGger:THReshold 20"
460 !Adjusts the trigger level in dB below the expected input power level.
470 !
480 OUTPUT Test_set;"SETup:PCAL:WAVeform:TYPe DISCRETE"
490 !Chooses the discrete version of the measurement
500 !
510 OUTPUT Test_set;"SETup:PCAL:TRIGger:DELay 0"
520 !Adjusts the trigger delay; default value is 0; default unit is seconds;
530 ! adjusts the time the test set waits after a physical trigger event, before
540 ! the Analog to Digital Converter acquires waveform samples
550 !
560 ! The following section sets up data arrays for this measurement for the
570 ! HT BASIC programming language
580 RESTORE Time_specs
590 !Points to the first data item on or after the beginning of the
600 ! Time_specs subroutine.
610 !
620 READ Step_count
630 !Assigns Step_count to the first data item on or after the beginning
640 ! of the Time_specs subroutine.
650 !
660 ALLOCATE Center(1:Step_count),Width(1:Step_count)
670 !Dimensions the `Center' and `Width' arrays to contain the same number of
680 ! elements as the number of measurement intervals (Step_count); also
690 ! reserves computer memory for the arrays.
700 !
710 OUTPUT Test_set;"SETup:PCAL:STEP:COUNt ";Step_count
720 !Tells the Test Set how many measurement intervals it will perform
730 ! (Step_count).
740 !
750 FOR I=1 TO Step_count
760 !Creates separate `Center' and `Width' arrays from the data items.
770 READ Time_cent,Time_width
780 Center(I)=Time_cent
790 Width(I)=Time_width
800 NEXT I
810 !
820 OUTPUT Test_set;"SETup:PCAL:STEP:CENTer ";Center(*)
830 !Enters the center location of each measurement interval (from the
840 ! `Center' array) into the Test Set
850 !
860 OUTPUT Test_set;"SETup:PCAL:STEP:WIDth ";Width(*)
870 !Enters the center location of each measurement interval (from the
880 ! "Width" array) into the Test Set
890 !
900 !****Initialize the measurement & get results.****!
910 !-------------------------------------------------!
920 ALLOCATE Power_results(1:Step_count),Phase_results(1:Step_count),Freq_results(1:Step_count)
930 !Dimensions results arrays to contain the same number of elements as the
940 ! `Center' array and `Width' array; reserves computer memory for the arrays.
950 !
960 OUTPUT Test_set;"READ:PCAL?"
970 !Initiates the Phase & Amplitude vs. Time measurement and waits until
980 ! results are returned (or until the measurement timeout interval elapses).
990 !
1000 PRINT "*** Agilent E1968A Phase & Amplitude vs. Time Measurement ***"
1010 PRINT ""
1020 !
1030 PRINT "--> INSTRUCTIONS TO USER:"
1040 PRINT "--> Command the wireless device to transmit the test waveform"
1050 PRINT "--> (before the end of the measurement timeout interval)."
1060 PRINT ""
1070 ! If your program controls when your device begins transmitting, you must
1080 ! include at least a 250 millisecond wait time between: initializing the
1090 ! PAvT measurement (READ:PCAL? above); and when the DUT transmits the
1100 ! test waveform
1110 !
1120 ENTER 714;Integrity,Power_results(*),Phase_results(*),Freq_results(*)
1130 ! Read and sort the measurement results from the Test Set.
1140 !
1150 IF Integrity<>0 THEN ! If measurement integrity value does not equal
1160 ! zero, there is an error
1170 PRINT "Measurement Error; Integrity Value = ";Integrity
1180 PRINT ""
1190 ELSE
1200 END IF
1210 !
1220 PRINT "Reference Measurement Data:"
1230 PRINT " Absolute Power Reference = ";Power_results(1);" dBm"
1240 PRINT " Phase error = 0 degrees by definition."
1250 PRINT " Frequency Error (vs. meas. frequency) = ";Freq_results(1);" Hz"
1260 PRINT ""
1270 ! First measurement results are reference values; see documentation.
1280 !
1290 PRINT "Results below are compared to the Reference Measurement Data above."
1300 PRINT ""
1310 !
1320 PRINT "Power Phase Frequency"
1330 PRINT "Difference Difference Difference"
1340 PRINT "in dB in degrees in Hz"
1350 PRINT "------------------------------------------------"
1360 !
1370 FOR I=2 TO Step_count! Reads and prints the results arrays (not including
1380 ! the first measurement results).
1390 PRINT Power_results(I);" ";Phase_results(I);" ";Freq_results(I)
1400 NEXT I
1410 !
1420 DEALLOCATE Power_results(*),Phase_results(*),Freq_results(*)
1430 ! Releases computer memory allocated for arrays
1440 !
1450 STOP
1460 ! Program stops here; subroutines continue below
1470 !
1480 !
1490 Time_specs: !
1500 !
1510 DATA 20 ! The first data item is equal to the number of measurement
1520 ! intervals being specified (Step_count).
1530 !
1540 ! The following data values are used by this program to set the measurement
1550 ! interval center time (in seconds) and the measurement interval width (in
1560 ! seconds) for each step of a discrete input waveform.
1570 ! (These values do not apply to a continuous waveform measurement).
1580 !
1590 ! center (sec), width (sec)
1600 DATA .0005,.0008
1610 DATA .0015,.0008
1620 DATA .0025,.0008
1630 DATA .0035,.0008
1640 DATA .0045,.0008
1650 DATA .0055,.0008
1660 DATA .0065,.0008
1670 DATA .0075,.0008
1680 DATA .0085,.0008
1690 DATA .0095,.0008
1700 DATA .0105,.0008
1710 DATA .0115,.0008
1720 DATA .0125,.0008
1730 DATA .0135,.0008
1740 DATA .0145,.0008
1750 DATA .0155,.0008
1760 DATA .0165,.0008
1770 DATA .0175,.0008
1780 DATA .0185,.0008
1790 DATA .0195,.0008
1800 !
1810 DEALLOCATE Center(*),Width(*)
1820 ! Releases computer memory allocated for arrays
1830 !
1840 END
1850 !*****End of main program.****!
1860 !
1870 !
1880 Timeout: SUB Timeout
1890 PRINT "Program timeout!!"
1900 CLEAR 7
1910 CLEAR 714
1920 SUBEND
1930 !
Returned Values
This program sorts the measurement results into three arrays: Power_results, Phase_results and Freq_result. This program returns the arrays in three comma separated columns. The first column displays the Power results, the second displays the Phase results and the third displays the Frequency results.
Note: The first row of values returned by this program are absolute measurements and all subsequent rows are measured results relative to the absolute values. See
Phase and Amplitude Measurement Results for a Discrete Waveform
for more information.
top
of page