Programming a TX Dynamic Power Measurement

Last updated: January 16, 2009

This section provides an example of how to make a TX dynamic power measurement via remote program.

The following program example assumes that the test set is inActive Cell Operating mode and the UE is connected to the RF IN/OUT connector.

The basic procedure to measure TX dynamic power is as follows:

Set the test set's receiver to the proper power and frequency using the RFANalyzer:CONTrol:POWer:AUTO , RFANalyzer:MANual:POWer[:SELected] and RFANalyzer:MANual:MEASurement[:MFRequency] commands.
Set the TX dynamic power setup parameters to match your UE's power sequence using the SETup:WTDPower commands.
Place your UE into the test mode required for performing TX dynamic power and order it to transmit continuously at the initial transmit power level.
Initiate (arm) the TX dynamic power measurement using the INITiate:<measurement mnemonic>[:ON] command.
Using the UE's test mode interface, command your UE to generate the RF rise needed to trigger the measurement.
When the measurement is finished, use the FETCh:WTDPower commands to obtain the measurement results.

Programming Example

 
10       CLEAR SCREEN
20       DIM Dypow_res$[3400]
30       DIM Dynamic_val(200)
40       Testset=714
50            !
60            !***Set up measurement parameters***
70            !
80       OUTPUT Testset;"SETup:WTDPower:TIMeout 10"
90            ! Sets Measurement Timeout to 10 seconds
100       OUTPUT Testset;"RFANalyzer:CONTrol:POWer:AUTO OFF"
110           ! Sets Power Control to manual mode
120       OUTPUT Testset;"RFANalyzer:MANual:POWer 20"
130           ! Sets Manual Power to 20 dBm
140       OUTPUT Testset;"RFANalyzer:MANual:MEASurement 1900 MHZ"
150           ! Sets Measurement Frequency to 1900 MHz
160       OUTPUT Testset;"SETup:WTDPower:STEP -3"
170           ! Sets Power Step Size to -3 dB
180       OUTPUT Testset;"SETup:WTDPower:STEP:COUNt 9"
190           ! Sets Number of Power Steps to 9
200       OUTPUT Testset;"SETup:WTDPower:STEP:TIME MS20"
210           ! Sets Power Step Time to 20 ms
220           !
230           !***Initiate the measurement***
240           !
250       OUTPUT Testset;"INITiate:WTDPower"
260           ! Initiates the measurement
270           !
280       PRINT "Command the UE to trigger the measurement"
290       PRINT "and begin its step down power sequence"
300           !
310           !***Obtain measurement results***
320           !
330       OUTPUT Testset;"FETCh:WTDPower:COUNt?"
340       ENTER Testset;Numpowmeas
350           ! Determines the number of power results available
360       OUTPUT Testset;"FETCh:WTDPower?"
370       ENTER Testset;Integrity,Dypow_res$
380           ! Fetches the integrity indicator and power results
390           !
400           !***Print measurement results***
410           !
420       PRINT
430       PRINT "Integrity Indicator = ";Integrity
440       PRINT "The number of power meas results available = ";Numpowmeas
450       FOR I=1 TO Numpowmeas
460           Dynamic_mkr=((I-1)*17)
470             ! Sets up a marker that will jump to each comma in the ascii string
480           Dynamic_val(I)=VAL(Dypow_res$[Dynamic_mkr+1;Dynamic_mkr+16])
490             ! Convert ascii to a numeric value
500           PRINT
510           PRINT "Power of step";I-1;"= ";Dynamic_val(I);"dBm/5 MHz"
520       NEXT I
530           !
540       END

A sample output from this program example is shown below:

Programming a TX Dynamic Power Measurement

Programming Example

Related Topics