Programming a Dynamic Power Measurement

Programming Example

The following program shows how to use the Dynamic Power measurement to measure a GSM mobile station's power control level capability when using SACCH (Slow Associated Control Channel) TX Level Signaling. This technique is based upon the RF power control characteristics specified in GSM 05.08 section 6.3.0 Release 1997.

 
10    ! INITIALIZE VARIABLES IN THE TEST
20    !
30    Sacch_time=TIMEDATE  ! Set up a variable to capture test time
40    OPTION BASE 1  ! Set default lower bound of array subscripts to 1
50    REAL Integ1(100),Txp1(100),Power(300)
60    REAL Integ2(100),Txp2(100),Integ3(100),Txp3(100)
70    REAL Start_power,Stop_power
80    INTEGER Test_set,I,Start_level,Stop_level
90    Test_set=714
100   Start_level=5
110   Start_power=33.0
120   Stop_level=15
130   Stop_power=13.0
140   !
150   OUTPUT Test_set;"RFAN:EXP:POW 33"  ! Set expected power
160   OUTPUT Test_set;"SYST:CORR -1.2"   ! Set value to compensate for cable loss
170   !
180   ! SETUP DPOW PARAMETERS
190   OUTPUT Test_set;"SET:DPOW:CONT OFF;EMD 2"
200   OUTPUT Test_set;"SET:DPOW:COUN:NUMBER 300"  ! Set the number of bursts high enough
210                                               ! to capture all 10 power level changes
220   OUTPUT Test_set;"CALL:SIGN:MS:TXL:FACCH 1" ! Switch on FACCH mode
230   !
240   ! CHANGE POWER LEVEL FROM 5 TO 15
250   OUTPUT Test_set;"CALL:MS:TXL:SEQ ";Start_level
260   OUTPUT Test_set;"CALL:SIGN:MS:TXL:FACCH 0"  ! Switch off FACCH signaling - only
270                                               ! SACCH header is used
280   OUTPUT Test_set;"CALL:MS:TXL:SEQ ";Stop_level
290   !
300 ! A SHORT WAIT MIGHT BE NEEDED HERE TO ENSURE 100 PERCENT RELIABILITY OF MEASUREMENT
310 ! THIS MAY BE DEPENDENT ON THE PHONE AND IS TO ENSURE THAT VERY LAST POWER STEP IS
320 ! ALWAYS CAPTURED
330 ! WAIT .1
340   !
350   ! INITIATE DPOW MEASUREMENT AND FETCH RESULTS
360   OUTPUT Test_set;"INIT:DPOW"
370   REPEAT
380     OUTPUT 714;"INIT:DONE?"
390     ENTER 714;Meas_complete$
400   UNTIL Meas_complete$="DPOW"
410   OUTPUT Test_set;"FETC:DPOW?"
420   ENTER Test_set;Integ1(*),Txp1(*)
430   OUTPUT Test_set;"FETC:DPOW:RANG2?"
440   ENTER Test_set;Integ2(*),Txp2(*)
450   OUTPUT Test_set;"FETC:DPOW:RANG3?"
460   ENTER Test_set;Integ3(*),Txp3(*)
470   !
480   ! LOAD TXP RESULTS WHICH HAVE VALID INTEGRITY INTO ARRAY
490   !
500   ! PROCESS BURSTS 1 TO 100
510   K=1
520     FOR J=1 TO 100
530       IF Integ1(J)=0 THEN
540         Power(K)=Txp1(J)
550         K=K+1
560       END IF
570     NEXT J
580   ! PROCESS BURSTS 101 TO 200
590     FOR J=1 TO 100
600       IF Integ2(J)=0 THEN
610         Power(K)=Txp2(J)
620         K=K+1
630       END IF
640     NEXT J
650   ! PROCESS BURSTS 201 TO 300
660     FOR J=1 TO 100
670       IF Integ3(J)=0 THEN
680         Power(K)=Txp3(J)
690         K=K+1
700       END IF
710     NEXT J
720   !
730   PRINT
740   !
750   ! PRINT MEASUREMENT RESULTS
760   PRINT "Measured TX Levels from 5 to 15 using SACCH Method"
770   PRINT
780   I=1
790   FOR J=Start_level TO Stop_level
800     LOOP
810       IF I=(K-1) THEN
820         PRINT "MS TX LEVEL=";J,"MEASURED POWER=";PROUND(Power(I),-2)
830         GOTO 920
840       END IF
850     EXIT IF (PROUND(Power(I),-2)-PROUND(Power(I+1),-2))>=.8
860       I=I+1
870     END LOOP
880     PRINT "MS TX LEVEL=";J,"MEASURED POWER=";Power(I)
890     I=I+1
900   NEXT J
910   !
920   ! PRINT TOTAL TIME FOR PROGRAM TO COMPLETE
930   PRINT "Total Test Time=";PROUND(TIMEDATE-Sacch_time,-2);"Seconds"
940   END

Returned Values

The measurements returned by this program are:

• Integ1 , Integ2 , and Integ3 return the measurement integrity indicators for each of the ranges used when the Dynamic Power measurement is made over 300 bursts (0 means a successful measurement with no errors). If you require more details, see Integrity Indicator .
• Txp1() , Txp2() , and Txp3() return the average TX power results for each of the ranges used over 300 bursts. For example, Txp1() returns average TX power results for bursts 1 to 100.
• Power() returns average TX power results for all bursts which have been successfully measured with no errors. That is, only results with an integrity indicator of 0 are contained in Power() . This program does not display the entire contents of the Power() array. It only displays the results which correlate with power level changes 5 to 15.
• Sacch_time returns the total test time.

Related Topics

Dynamic Power Measurement Description

SETup:DPOWer

INITiate

FETCh:DPOWer